Impatient Perl
version: 29 April 2004
Copyright 2004 Greg London
Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled "GNU Free Documentation License".
For more information, or for the latest version of this work, go to:
This document was created using OpenOffice version 1.1.0
(which exports directly to PDF)
running RedHat Linux
on a x86 machine from
http://www.penguincomputing.com
Table of Contents
1 The Impatient Introduction to Perl 6
1.1 The history of perl in 100 words or less 6
1.2 Basic Formatting for this Document 6
1.3 Do You Have Perl Installed 7
1.4 Your First Perl Script, EVER 7
1.7 Cheap Reference Material 9
2 Storage 11
2.1 Scalars 11
2.1.1.2 Single quotes versus Double quotes 12
2.1.1.9 join 14
2.1.1.10 qw 14
2.1.2.3 abs 15
2.1.2.4 int 15
2.1.2.5 trigonometry (sin,cos,tan) 16
2.1.2.7 sqrt 16
2.1.2.8 natural logarithms(exp,log) 17
2.1.2.9 random numbers (rand, srand) 17
2.1.3 Converting Between Strings and Numbers 18
2.1.4 Undefined and Uninitialized Scalars 20
2.1.5.2 TRUE 22
2.1.5.4.4 Assignment Precedence 25
2.1.5.4.5 Flow Control Precedence 25
2.2 Arrays 27
2.2.5 unshift( @array, LIST) 30
2.2.10 Undefined and Uninitialized Arrays 33
2.3 Hashes 34
2.3.1 exists ( $hash{$key} ) 35
2.3.2 delete ( $hash{key} ) 36
2.5.2 References to Named Referents 46
2.5.5 Complex Data Structures 49
2.5.5.2 Multidimensional Arrays 51
2.5.6 Stringification of References 51
3.1 Labels 54
4 Packages and Namespaces and Lexical Scoping 55
4.2 Declaring Package Variables With our 56
4.3 Package Variables inside a Lexical Scope 57
4.6.1 Reference Count Garbage Collection 60
4.6.2 Garbage Collection and Subroutines 60
4.7 Package Variables Revisited 61
4.8 Calling local() on Package Variables 62
5.4 Data::Dumper and subroutines 65
5.5 Passing Arguments to/from a Subroutine 66
5.6 Accessing Arguments inside Subroutines via @_ 66
5.7 Dereferencing Code References 67
5.9 Subroutine Return Value 68
5.11 Using the caller() Function in Subroutines 69
5.12 The caller() function and $wantarray 70
5.13 Using wantarray to Create Context Sensitive Subroutines 71
6 Compiling and Interpreting 71
9 The use Statement, Formally 74
9.3 The PERL5LIB and PERLLIB Environment Variables 75
9.5 MODULENAME -> import (LISTOFARGS) 76
9.6 The use Execution Timeline 77
10 bless() 77
11.3 INVOCANT->isa(BASEPACKAGE) 83
11.4 INVOCANT->can(METHODNAME) 83
13.1 Class 87
13.3 SUPER 88
14.1 Modules 90
14.4 Methods 91
14.6 Overriding Methods and SUPER 92
15 CPAN 92
15.3 Plain Old Documentation (POD) and perldoc 95
15.4 Creating Modules for CPAN with h2xs 95
17.1 @ARGV 97
18.1 open 102
18.2 close 102
18.3 read 102
18.4 write 103
18.5 File Tests 104
19 Operating System Commands 105
19.1 The system() function 105
19.2 The Backtick Operator 106
19.3 Operating System Commands in a GUI 106
20.1 Variable Interpolation 108
20.5 Capturing and Clustering Parenthesis 111
20.6.1 Metacharacters Within Character Classes 113
20.7 Shortcut Character Classes 113
20.8 Greedy (Maximal) Quantifiers 114
20.9 Thrifty (Minimal) Quantifiers 114
20.10 Position Assertions / Position Anchors 115
20.11 Modifiers 117
20.11.2 The m And s Modifiers 118
20.12 Modifiers For m{} Operator 121
20.13 Modifiers for s{}{} Operator 121
20.14 Modifiers for tr{}{} Operator 121
This document is for people who either want to learn perl or are already programming in perl and just do not have the patience to scrounge for information to learn and use perl. This document should also find use as a handy desk reference for some of the more common perl related questions.
In the mid 1980s, Larry Wall was working as a sys-admin and found that he needed to do a number of common, yet oddball functions over and over again. And he did not like any of the scripting languages that were around at the time, so he invented Perl. Version 1 was released circa 1987. A few changes have occurred between then and now. The current version of Perl has exceeded 5.8.0 and is a highly recommended upgrade.
Perl 6 is on the drawing board as a fundamental rewrite of the language. It is not available yet, and probably will not be available for some time.
This document is formatted into text sections, code sections, and shell sections. This sentence is part of a text section. Text sections will extend to the far left margin and will use a non-monospaced font. Text sections contain descriptive text.
Code sections are indented.
They also use a monospaced font.
This is a code section, which represents
code to type into a script.
You will need to use a TEXT EDITOR,
not a WORD PROCESSOR to create these files.
Generally, the code is contained in one file,
and is executed via a shell command.
If the code section covers multiple files,
each file will be labeled.
###filename:MyFile.pm
This code will be placed in a
file called MyFile.pm
#!/usr/local/bin/perl
###filename:myscript.pl
This code will be placed in a file
called myscript.pl
The first line of myscript.pl will be the
line with #!/usr/local/bin/perl
> shell sections are indented like code sections
> shell sections also use monospaced fonts.
> shell sections differ from code sections in
> that shell sections start with a '>' character
> which represents a shell prompt.
> shell sections show commands to type on
> the command line.
> shell sections also show the output of a script,
> if any exists.
> In simple examples, the code is shown in a
> code section, immediately followed by the output
> from running the script. The command to run
> the script is dropped to save space.
As an example, the code for a simple "Hello World" script is shown here. It can be typed into a file of any name. The name of the file is not important. The command to execute the script is not important either. In this example, the code is important, and the output is important, so they are they only things shown.
print "Hello World\n";
> Hello World
THIS DOCUMENT REFERS TO (LI/U)NIX PERL ONLY. Much of this will translate to Mac Perl and Windows Perl, but the exact translation will be left as an exercise to the reader.
To find out if you have perl installed and its version:
> perl -v
You should have at least version 5.004. If you have an older version or if you have no perl installed at all, you can download it for free from
CPAN is an acronym for Comprehensive Perl Archive Network. The CPAN site contains the latest perl for download and installation, as was as a TON of perl modules for your use.
If you are a beginner, get your sys-admin to install perl for you. Even if you are not a beginner, get your sys-admin to install perl for you.
Find out where perl is installed:
> which perl
/usr/local/bin/perl
Create a file called hello.pl using your favorite text editor. Type in the following:
#!/usr/bin/env perl
use warnings;
use strict; # comment
use Data::Dumper;
print "Hello World \n";
(The #! on the first line is sometimes pronounced "shebang")
(The .pl extension is simply a standard accepted extension for perl scripts.)
Run the script:
> perl hello.pl
Hello World
This calls perl and passes it the name of the script to execute. You can save yourself a little typing if you make the file executable:
> chmod +x hello.pl
And then run the script directly.
> hello.pl
Hello World
If "." is not in your PATH variable, you will have to run the script by typing:
> ./hello.pl
HOORAY! Now go update your resume.
Anything from a # character to the end of the line is a comment.
EVERY perl script should have this line:
use warnings; use strict; use Data::Dumper;
All the code examples are assumed to have the following script header, unless otherwise stated:
#!/usr/local/bin/perl
use warnings;
use strict;
use Data::Dumper;
Optionally, you may try the header shown below. It uses your PATH environment variable to determine which perl executable to run. If you need to have different versions of perl installed on your system, you can control which version of perl they will run by changing your PATH variable without having to change your script.
#!/usr/bin/env perl
use warnings;
use strict;
use Data::Dumper;
You can get quick help from the standard perl installation.
> perl -h
> perldoc
> perldoc -h
> perldoc perldoc
FAQs on CPAN: http://www.cpan.org/cpan-faq.html
Mailing Lists on CPAN: http://list.cpan.org
More free documentation on the web: http://www.perldoc.com
Still more free documentation on the web: http://learn.perl.org
"Programming Perl" by Larry Wall, Tom Christiansen, and Jon Orwant. Highly recommended book to have handy at all times. It is sometimes referred to as the "Camel Book" by way of the camel drawing on its cover. The publisher, O'Reilly, has printed enough computer books to choke a, well, camel, and each one has a different animal on its cover. Therefore if you hear reference to some animal book, it is probably an O'Reilly book. Well, unless its the "Dragon Book", because that refers to a book called "Compilers" by Aho, Sethi, and Ullman. Anyways, when I get a graphic that I like, I will slap it on the front cover and give this document a picture name as well.
PERL: Originally, "Pearl" shortened to "Perl" to gain status as a 4-letter word. Now considered an acronym for Practical Extraction and Report Language, as well as Petty Ecclectic Rubbish Lister. The name was invented first. The acronyms followed.
CPAN: Comprehensive Perl Archive Network. See http://www.cpan.org for more.
DWIM: Do What I Mean. Once upon a time, the standard mantra for computer inflexibility was this: "I really hate this darn machine, I wish that they would sell it. It never does what I want, but only what I tell it." DWIM-iness is an attempt to embed perl with telepathic powers such that it can understand what you wanted to write in your code even though you forgot to actually type it. Well, alright, DWIM is just a way of saying the language was designed by some really lazy programmers so that you could be even lazier than they were. (They had to write perl in C, so they could not be TOO lazy.)
AUTOVIVIFY: "auto" meaning "self". "vivify" meaning "alive". To bring oneself to life. Generally applies to perl variables that can grant themselves into being without an explicit declaration from the programmer. Part of perl's DWIM-ness. "Autovivify" is a verb. The noun form is "autovivification". Sometimes, autovivification is not what you meant your code to do, and for some reason, when "do what I mean" meets autovivification in perl, autovivification wins. And now, a Haiku:
Do What I Mean and
Autovivification
sometimes unwanted
TMTOWTDI: There is More Than One Way To Do It. An acknowledgement that any programming problem has more than one solution. Rather than have perl decide which solution is best, it gives you all the tools and lets you choose. This allows a programmer to select the tool that will let him get his job done. Sometimes, it gives a perl newbie just enough rope to hang himself.
Foo Fighters: A phrase used around the time of WWII by radar operators to describe a signal that could not be explained. Later became known as a UFO. This has nothing to do with perl, except that "foo" is a common variable name used in perl.
Fubar: Another WWII phrase used to indicate that a mission had gone seriously awry or that a piece of equipment was inoperative. An acronym for Fouled Up Beyond All Recognition and similar interpretations. This has nothing to do with perl either, except that fubar somehow got mangled into foobar, and perl is often awash in variables named "foo" and "bar", especially if the programmer wishes to hide the fact that he did not understand his code well enough to come up with better names. If you use a $foo variable in your code, you deserve to maintain it.
Perl has three basic storage types: Scalars, Arrays, Hashes.
The most basic storage type is a Scalar.
Arrays and Hashes use Scalars to build more complex data types.
Scalars are preceded with a dollar sign sigil. A "$" is a stylized "S".
Scalars can store Strings, Numbers (integers and floats), References, and Filehandles.
Perl is smart enough to know which type you are putting into a scalar and handle it.
my $diameter = 42;
my $pi = 3.1415;
my $initial = 'g';
my $name = 'John Doe';
my $ref_to_name = \$name
Without "use strict;" and without declaring a variable with a "my", using a variable causes perl to create one and initialize it to "" or 0. This is called autovivication.
Autovivify : to bring oneself to life.
In most common situations, autovivication is handy. However, in certain situations, autovivification can be an unholy monster.
my $circumference = $pie * $diameter;
# oops, $pie doesn't exist. Autovivified to zero,
# therefore $circumference is zero.
Without use warnings; use strict; perl will autovivify a new variable called "pie", initialize it to zero, and assume that is what you meant to do. There is no reason that warnings and strictness should not be turned on in your scripts.
Scalars can store strings. You do not have to declare the length of the string, perl just handles it for you automatically.
String literals must be in single or double quotes or you will get an error.
print hello;
Error: Unquoted string "hello" may clash with reserved word
You can use single quotes or double quotes to set off a string literal:
my $name = 'mud';
my $greeting = "hello, $name\n";
print $greeting;
> hello, mud
You can also create a list of string literals using the qw() function.
my ($first,$last)=qw( John Doe );
print "first is '$first'\n";
print "last is '$last'\n";
> first is 'John'
> last is 'Doe'
Single quoted strings are a "what you see is what you get" kind of thing.
my $name = 'mud';
print 'hello $name';
> hello $name
Double quotes means that you get SOME variable interpolation during string evaluation. Complex variables, such as a hash lookup cannot be put in double quoted strings and get interpolated properly.
my $name = 'mud';
print "hello $name \n";
> hello mud
Note: a double-quoted "\n" is a new-line character.
You may get rid of a newline character at the end of a string by chomp-ing the string. The chomp function removes one new line from the end of the string even if there are multiple newlines at the end. If there are no newlines, chomp leaves the string alone. The return value of chomp is what was chomped (seldom used).
My $string = "hello world\n";
chomp($string);
warn "string is '$string' \n"
> string is 'hello world' ...
String concatenation uses the period character "."
my $fullname = 'mud' . "bath";
Repeat a string with the "x" operator.
my $line = '-' x 80; # $line is eighty hypens
Find out how many characters are in a string with length().
my $len = length($line); # $len is 80
substr ( STRING_EXPRESSION, OFFSET, LENGTH);
Spin, fold, and mutilate strings using substr(). The substr function gives you fast access to get and modify chunks of a string. You can quickly get a chunk of LENGTH characters starting at OFFSET from the beginning or end of the string (negative offsets go from the end). The substr function then returns the chunk.
my $chunk = substr('the rain in spain', 9, 2);
warn "chunk is '$chunk'";
> chunk is 'in' ...
The substr function can also be assigned to, replacing the chunk as well. You need a string contained in a variable that can be modified, rather than using a constant literal in the example above.
my $string = 'the rain in spain';
substr($string, 9, 2) = 'beyond';
warn "string is '$string'";
> string is 'the rain beyond spain' ...
split(/PATTERN/, STRING_EXPRESSION,LIMIT);
Use the split function to break a string expression into components when the components are separated by a common substring pattern. For example, tab separated data in a single string can be split into separate strings.
my $tab_sep_data = "John\tDoe\tmale\t42";
my ($first,$last,$gender,$age)
= split(/\t/, $tab_sep_data);
You can break a string into individual characters by calling split with an empty string pattern "". The /PATTERN/ in split() is a Regular Expression, which is complicated enough to get its own chapter.
join('SEPARATOR STRING', STRING1, STRING2, ...);
Use join to stitch a list of strings into a single string.
my $string = join(" and ",
'apples', 'bananas', 'peaches');
warn "string is '$string'";
> string is 'apples and bananas and peaches'...
The qw() function takes a list of barewords and quotes them for you.
my $string =
join(" and ", qw(apples bananas peaches));
warn "string is '$string'";
> string is 'apples and bananas and peaches'...
Perl generally uses floats internally to store numbers. If you specify something that is obviously an integer, it will use an integer. Either way, you simply use it as a scalar.
my $days_in_week = 7; # scalar => integer
my $temperature = 98.6; # scalar => float
Perl allows several different formats for numeric literals, including integer, floating point, and scientific notation, as well as decimal, octal, and hexadecimal.
Binary numbers begin with "0b"
hexadecimal numbers begin with "0x"
Octal number begin with a "0"
All other numeric literals are assumbed to be base 10.
my $solar_temp_c = 1.5e7; # centigrade
my $solar_temp_f = 27_000_000.0; # fahrenheit
my $base_address = 01234567; # octal
my $high_address = 0xfa94; # hexadecimal
my $low_address = 0b100101; # binary
Use abs to get the absolute value of a number.
my $var1 = abs(-3.4); # var1 is 3.4
my $var2 = abs(5.9); # var2 is 5.9
Use "int" to convert a floating point number to an integer. Note that this truncates everything after the decimal point, which means you do NOT get rounding. Truncating means that positive numbers always get smaller and negative numbers always get bigger.
my $price = 9.95;
my $dollars = int ($price);
# dollars is 9, not 10! false advertising!
my $y_pos = -5.9;
my $y_int = int($y_pos);
# y_int is -5 (-5 is "bigger" than -5.9)
If you want to round a float to the nearest integer, you will need to write a bit of code. One way to accomplish it is to use sprintf:
my $price = 9.95;
my $dollars = sprintf("%.0f", $price);
# dollars is 10
The sin, cos, and tan functions return the sine, cosine, and tangent of a value given in RADIANS. If you have a value in DEGREES, multiply it by (pi/180) first.
my $angle = 45; # 45 deg
my $radians = $angle * ( 3.14 / 180 ); # .785 rad
my $sine_deg = sin($angle); # 0.707
my $sine_rad = sin($radians); # 0.707
If you need inverse sine, cosine, or tangent, then use the Math::Trig module on CPAN.
Use the "**" operator to raise a number to some power.
my $seven_squared = 7 ** 2; # 49
my $five_cubed = 5 ** 3; #125
my $three_to_the_fourth = 3 ** 4; # 81
Use fractional powers to take a root of a number:
my $square_root_of_49 = 49 ** (1/2); # 7
my $cube_root_of_125 = 125 ** (1/3); # 5
my $fourth_root_of_81 = 81 ** (1/4); # 3
Standard perl cannot handle imaginary numbers. Use the Math::Complex module on CPAN.
Use sqrt to take the square root of a positive number.
my $square_root_of_123 = sqrt(123); # 11.0905
The exp function returns e to the power of the value given. To get e, call exp(1);
my $value_of_e = exp(1); # 2.7183
my $big_num= exp(42); # 2.7183 ** 42 = 1.7e18
The log function returns the inverse exp() function, which is to say, log returns the number to which you would have to raise e to get the value passed in.
my $inv_exp = log($big_num); # inv_exp = 42
If you want another base, then use this subroutine:
sub log_x_base_b {return log($_[0])/log($_[1]);}
# want the log base 10 of 12345
# i.e. to what power do we need to raise the
# number 10 to get the value of 12345?
my $answer = log_x_base_b(12345,10); # answer = 4.1
Note that inverse natural logs can be done with exponentiation, you just need to know the value of the magic number e (~ 2.718281828). The exp function is straightforward exponentiation:
# big_num = 2.7183 ** 42 = 1.7e18
my $big_num = $value_of_e ** 42;
Natural logarithms simply use the inverse of the value (i.e. 1/value) with exponentiation.
# inv_exp = 2.7183 ** (1/1.7e18) = 42
my $inv_exp = $value_of_e ** (1/$big_num);
The rand function is a pseudorandom number generator (PRNG).
If a value is passed in, rand returns a number that satisfies ( 0 <= return <=input )
If no value is passed in, rand returns a number in the range ( 0 <= return < 1 )
The srand function will seed the PRNG with the value passed in. If no value is passed in, srand will seed the PRNG with something from the system that will give it decent randomness. You can pass in a fixed value to guarantee the values returned by rand will always follow the same sequence (and therefore are predictable). You should only need to seed the PRNG once. If you have a version of perl greater than or equal to 5.004, you should not need to call it at all, because perl will call srand at startup.
Many languages require the programmer to explicitely convert numbers to strings before printing them out and to convert strings to numbers before performing arithemetic on them. Perl is not one of these languages.
Perl will attempt to apply Do What I Mean to your code and just Do The Right Thing. There are two basic conversions that can occur: stringification and numification.
Stringify: Converting something other than a string to a string form.
Perl will automatically convert a number (integer or floating point) to a string format before printing it out.
my $mass = 7.3;
my $volume = 4;
warn "mass is '$mass'\n";
warn "volume is '$volume'\n";
> mass is '7.3' ...
> volumn is '4' ...
Even though $mass is stored internally as a floating point number and $volume is stored internally as an integer, the code did not have to explicitely convert these numbers to string format before printing them out. Perl will attempt to convert the numbers into the appropriate string representation. If you do not want the default format, use sprintf.
If you want to force stringification, simply concatenate a null string onto the end of the value.
my $mass = 7.3; # 7.3
my $string_mass = $mass .= ''; # '7.3'
Use sprintf to control exactly how perl will convert a number into string format.
sprintf ( FORMAT_STRING, LIST_OF_VALUES );
For example:
my $pi = 3.1415;
my $str = sprintf("%06.2f",$pi);
warn "str is '$str'";
> str is '003.14' ...
Decoding the above format string:
% => format
0 => fill leading spaces with zero
6 => total length, including decimal point
.2 => put two places after the decimal point
f => floating point notation
To convert a number to a hexadecimal, octal, binary, or decimal formated string, use the following FORMAT_STRINGS:
hexadecimal "%lx" The letter 'l' (L)
octal "%lo" indicates the input is
binary "%lb" an integer, possibly
decimal integer "%ld" a Long integer.
decimal float "%f"
scientific "%e"
Numify: Converting something other than a number to a numeric form.
Sometimes you have string information that actually represents a number. For example, a user might enter the string "19.95" which must be converted to a float before perl can perform any arithemetic on it.
You can force numification of a value by adding integer zero to it.
my $user_input = '19.95'; # '19.95'
my $price = $user_input+0; # 19.95
If the string is NOT in base ten format, then use oct() or hex()
The oct function can take a string that fits the octal, hexadecimal, or binary format and convert it to an integer.
binary formatted strings start with "0b"
hexadecimal formatted strings start with "0x"
all other numbers are assumed to be octal strings,
Note: even though the string might not start with a zero (as required by octal literals), oct will assume the string is octal. Which means calling oct() on a decimal number would be a bad thing.
To handle a string that could contain octal, hexadecimal, binary, OR decimal strings, you could assume that octal strings must start with "0". Then, if the string starts with zero, call oct on it, else assume its decimal. This example uses regular expressions and a tertiary operator, which are explained later.
my $num = ($str=~m{^0}) ? oct($str) : $str + 0;
The hex() function takes a string in hex format and converts it to integer. The hex() function is like oct() except that hex() only handles hex base strings, and it does not require a "0x" prefix.
All the examples above initialized the scalars to some known value before using them. You can declare a variable but not initialize it, in which case, the variable is undefined.
If you use a scalar that is undefined, perl will stringify or numify it based on how you are using the variable.
An undefined scalar stringifies to an empty string: ""
An undefined scalar numifies to zero: 0
Without warnings or strict turned on, this conversion is silent. With warnings/strict on, the conversion still takes place, but a warning is emitted.
Since perl automatically performs this conversion no matter what, there is no string or arithematic operation that will tell you if the scalar is undefined or not.
Use the defined() function to test whether a scalar is defined or not.
If the scalar is defined, the function returns a boolean "true" (1)
If the scalar is NOT defined, the function returns a boolean "false" ("").
If you have a scalar with a defined value in it, and you want to return it to its uninitialized state, assign undef to it. This will be exactly as if you declared the variable with no initial value.
my $var; # undef
print "test 1 :";
if(defined($var)) {print "defined\n";}
else {print "undefined\n";}
$var = 42; # defined
print "test 2 :";
if(defined($var)) {print "defined\n";}
else {print "undefined\n";}
$var = undef; # undef as if never initialized
print "test 3 :";
if(defined($var)) {print "defined\n";}
else {print "undefined\n";}
> test 1 :undefined
> test 2 :defined
> test 3 :undefined
Perl does not have a boolean "type" per se. Instead, perl interprets scalar strings and numbers as "true" or "false" based on some rules:
1) Strings "" and "0" are FALSE, any other string or stringification is TRUE
2) Number 0 is FALSE, any other number is TRUE
3) all references are TRUE
4) undef is FALSE
Note that these are SCALARS. Any variable that is not a SCALAR is first evaluated in scalar context, and then treated as a string or number by the above rules. The scalar context of an ARRAY is its size. An array with one undef value has a scalar() value of 1 and is therefore evaluated as TRUE.
A subroutine returns a scalar or a list depending on the context in which it is called. To explicitely return FALSE in a subroutine, use this:
return wantarray() ? () : 0; # FALSE
This is sufficiently troublesome to type for such a common thing that an empty return statement within a subroutine will do the same thing:
return; #FALSE
The following scalars are interpreted as FALSE:
integer 0 # false
float 0.0 # false
string '0' # false
string '' # false
undef # false
ALL other values are interpreted as TRUE, which means the following scalars are considered TRUE, even though you might not have expected them to be false.
string '0.0' # true
string '00' # true
string 'false' # true
float 3.1415 # true
integer 11 # true
string 'yowser' # true
If you are doing a lot of work with numbers on a variable, you may wish to force numification on that variable ($var+0) before it gets boolean tested, just in case you end up with a string "0.0" instead of a float 0.0 and get some seriously hard to find bugs.
Note that the string '0.0' is TRUE, but ('0.0'+0) will get numified to 0, which is FALSE. If you are processing a number as a string and want to evaluate it as a BOOLEAN, make sure you explicitely NUMIFY it before testing its BOOLEANNESS.
Built in Perl functions that return a boolean will return an integer one (1) for TRUE and an empty string ("") for FALSE.
Comparison operators return booleans, specifically an integer 1 for true and a null string "" for false. The "Comparison" operator ("<=>" and "cmp") return a -1, 0, or +1, indicating the compared values are less than, equal to, or greater than. Distinct comparison operators exist for comparing strings and for comparing numbers.
|
Function |
String |
Numeric |
|---|---|---|
|
equal to |
eq |
== |
|
not equal to |
ne |
!= |
|
less than |
lt |
< |
|
greater than |
gt |
> |
|
less than or equal to |
le |
<= |
|
greater than or equal to |
ge |
>= |
|
Comparison (<-1, ==0,>1) |
cmp |
<=> |
Note that if you use a string compare to compare two numbers, you will get their alphabetical string comparison. Perl will stringify the numbers and then perform the compare. This will occur silently; perl will emit no warning. And if you wanted the numbers compared numerically but used string comparison, then you will get the wrong result when you compare the strings ("9" lt "100").
String "9" is greater than (gt) string "100".
Number 9 is less than (<=) number 100.
If you use a numeric operator to compare two strings, perl will attempt to numify the strings and then compare them numerically. Comparing "John" <= "Jacob" will cause perl to convert "John" into a number and fail miserably. However, if warnings/strict is not on, it will fail miserably and SILENTLY, assigning the numification of "John" to integer zero.
The numberic comparison operator '<=>' is sometimes called the "spaceship operator".
Perl has two sets of operators to perform logical AND, OR, NOT functions. The difference between the two is that one set has a higher precedence than the other set.
The higher precedence logical operators are the '&&', '||', and '!' operators.
|
function |
operator |
usage |
return value |
|---|---|---|---|
|
AND |
&& |
$one && $two |
if ($one is false) $one else $two |
|
OR |
|| |
$one || $two |
if ($one is true) $one else $two |
|
NOT |
! |
! $one |
if ($one is false) true else false |
The lower precedence logical operators are the 'and', 'or', 'not', and 'xor' operators.
|
function |
operator |
usage |
return value |
|---|---|---|---|
|
AND |
and |
$one and $two |
if ($one is false) $one else $two |
|
OR |
or |
$one or $two |
if ($one is true) $one else $two |
|
NOT |
not |
not $one |
if ($one is false) true else false |
|
XOR |
xor |
$one xor $two |
if ( ($one true and $two false) or ($one false and $two true) ) then return true else false |
Both sets of operators are very common in perl code, so it is useful to learn how precedence affects their behavior. But first, some examples of how to use them.
This subroutine has two input parameters ($left and $right) with default values (1.0 and 2.0). If the user calls the subroutine with missing arguments, the undefined parameters will instead receive their default values.
sub mysub
{
my( $left, $right )=@_;
$left ||= 1.0;
$right ||= 2.0;
# deal with $left and $right here.
}
The '||=' operator is a fancy shorthand. This:
$left ||= 1.0;
is exactly the same as this:
$left = $left || 1.0;
The open() function here will attempt to open $filename for reading and attach $filehandle to it. If open() fails in any way, it returns FALSE, and FALSE OR'ed with die() means that perl will evaluate the die() function to finish the logical evalutation. It won't complete because execution will die, but the end result is code that is actually quite readable.
open (my $filehandle, $filename)
or die "cant open";
The reason we used '||' in the first example and 'or' in the second example is because the operators have different precedence, and we used the one with the precedence we needed.
When working with an assignment, use '||' and '&&', because they have a higher precedence than (and are evaluated before) the assignement '='. The 'or' and 'and' operators have a precedence that is LOWER than an assignment, meaning the assignment would occur first, followed by any remaining 'and' and 'or' operators.
Right:
my $default = 0 || 1;
# default is 1
Wrong:
my $default = 0 or 1;
# default is 0
The second example is equivalent to this:
(my $default = 0) or 1;
which will ALWAYS assign $default to the first value and discard the second value.
When using logical operators to perform flow control, use 'or' and 'and' operators, because they have lower precedence than functions and other statements that form the boolean inputs to the 'or' or 'and' operator. The '||' and '&&' have higher precedence than functions and may execute before the first function call.
Right:
close $fh or die "Error:could not close";
Wrong:
close $fh || die "Error: could not close";
The second example is equivalent to this:
close ($fh || die "Error");
which will ALWAYS evaluate $fh as true, NEVER die, and close $fh. If close() fails, the return value is discarded, and the program continues on its merry way.
It is always possible to override precedence with parentheses, but it is probably better to get in the habit of using the right operator for the right job.
A reference points to the variable to which it refers. It is kind of like a pointer in C, which says "the data I want is at this address". Unlike C, you cannot manually alter the address of a perl reference. You can only create a reference to variables that are visible in your source code.
Create a reference by placing a "\" in front of the variable:
my $name = 'John';
my $age = 42;
my $name_ref = \$name;
my $age_ref = \$age;
Perl will stringify a reference so that you can print it and see what it is.
warn "age_ref is '$age_ref'";
> age_ref is 'SCALAR(0x812e6ec)' ...
This tells you that $age_ref is a reference to a SCALAR (which we know is called $age). It also tells you the address of the variable to which we are referring is 0x812e6ec.
You cannot referencify a string. I.E. you cannot give perl a string, such as "SCALAR(0x83938949)" and have perl give you a reference to whatever is at that address. Perl is pretty loosy goosey about what it will let you do, but not even perl is so crazy as to give people complete access to the system memory.
You can dereference a reference by putting an extra sigil (of the appropriate type) in front of the reference variable.
my $name = 'John';
my $ref_to_name = \$name;
my $deref_name = $$ref_to_name;
warn $deref_name;
> John ...
References are interesting enough that they get their own section. But I introduce them here so that I can introduce a really cool module that uses references: Data::Dumper. Data::Dumper will take a reference to ANYTHING and print out the thing to which it refers in a human readable form.
This does not seem very impressive with a reference to a scalar:
my $name = 'John';
my $ref_to_name = \$name;
warn Dumper \$ref_to_name;
> $VAR1 = \'John';
But this will be absolutely essential when working with Arrays and Hashes.
Scalars can store a filehandle. File IO gets its own section, but I introduce it here to give a complete picture of what scalars can hold.
Given a scalar that is undefined (uninitialized), calling open() on that scalar and a string filename will tell perl to open the file specified by the string, and store the handle to that file in the scalar.
open(my $fh, '>out.txt');
print $fh "hello world\n";
print $fh "this is simple file writing\n";
close($fh);
The scalar $fh in the example above holds the filehandle to "out.txt". Printing to the filehandle actually outputs the string to the file.
There is some magic going on there that I have not explained, but that is a quick intro to scalar filehandles.
Scalars can store STRINGS, NUMBERS (floats and ints), REFERENCES, and FILEHANDLES.
Stringify: to convert something to a string format
Numify: to convert something to a numeric format
The following scalars are interpreted as boolean FALSE:
(integer 0, float 0.0, string "0", string "", undef)
All other scalar values are interpreted as boolean TRUE.
Arrays are preceded with an ampersand sigil. The "@" is a stylized "a".
An array stores a bunch of scalars that are accessed via an integer index.
Perl arrays are ONE-DIMENSIONAL ONLY. (Do Not Panic.)
The first element of an array always starts at ZERO (0).
When you refer to an entire array, use the "@" sigil.
my @numbers = qw ( zero one two three );
When you index into the array, the "@" character changes to a "$"
my @numbers = qw ( zero one two three );
my $string = $number[2];
warn $string;
> two ...
The length of an array is not pre-declared. Perl autovivifies whatever space it needs.
my @months;
$months[1]='January';
$months[5]='May';
# $months[0] and $months[2..4] are autovivified
# and initialized to undef
print Dumper \@months;
> $VAR1 = [
> undef, # index 0 is undefined
> 'January', # $months[1]
> ${\$VAR1->[0]}, # this is same as undef
> ${\$VAR1->[0]}, # undef
> ${\$VAR1->[0]}, # undef
> 'May' # $months[5]
> ];
If you want to see if you can blow your memory, try running this piece of code:
my @mem_hog;
$mem_hog[10000000000000000000000]=1;
# the array is filled with undefs
# except the last entry, which is initialized to 1
Arrays can store ANYTHING that can be stored in a scalar
my @junk_drawer = ( 'pliers', 1,1,1, '*', '//',
3.14, 9*11, 'yaba', 'daba' );
Negative indexes start from the end of the array and work backwards.
my @colors = qw ( red green blue );
my $last=$colors[-1];
warn "last is '$last'";
> last is 'blue' ...
To get how many elements are in the array, use "scalar"
my @phonetic = qw ( alpha bravo charlie delta );
my $quantity = scalar(@phonetic);
warn $quantity;
> 4 ...
When you assign an entire array into a scalar variable, you will get the same thing, but calling scalar() is much more clear.
my @phonetic = qw ( alpha bravo charlie );
my $quant = @phonetic;
warn $quant;
> 3 ...
This is explained later in the "list context" section.
Use push() to add elements onto the end of the array (the highest index). This will increase the length of the array by the number of items added.
my @groceries = qw ( milk bread );
push(@groceries, qw ( eggs bacon cheese ));
print Dumper \@groceries;
> $VAR1 = [
> 'milk',
> 'bread',
> 'eggs',
> 'bacon',
> 'cheese'
> ];
Use pop() to get the last element off of the end of the array (the highest index). This will shorten the array by one. The return value of pop() is the value popped off of the array.
my @names = qw ( alice bob charlie );
my $last_name = pop(@names);
warn "popped = $last_name";
print Dumper \@names;
> popped = charlie ...
> $VAR1 = [
> 'alice',
> 'bob'
> ];
Use shift() to remove one element from the beginning/bottom of an array (i.e. at index zero). All elements will be shifted DOWN one index. The array will be shorted by one. The return value is the value removed from the array.
my @curses = qw ( fee fie foe fum );
my $start = shift(@curses);
warn $start;
warn Dumper \@curses;
> fee
> $VAR1 = [
> 'fie',
> 'foe',
> 'fum'
> ];
use unshift() to add elements to the BEGINNING/BOTTOM of an array (i.e. at index ZERO). All the other elements in the array will be shifted up to make room. This will length the array by the number of elements in LIST.
my @trees = qw ( pine maple oak );
unshift(@trees, 'birch');
warn Dumper \@trees;
> $VAR1 = [
> 'birch', # index 0
> 'pine', # old index 0, now 1
> 'maple', # 2
> 'oak' # 3
> ];
Use foreach to iterate through all the elements of a list. Its formal definition is:
LABEL foreach VAR (LIST) BLOCK
This is a control flow structure that is covered in more detail in the "control flow" section. The foreach structure supports last, next, and redo statements.
Use a simple foreach loop to do something to each element in an array:
my @fruits = qw ( apples oranges lemons pears );
foreach my $fruit (@fruits)
{ print "fruit is '$fruit'\n"; }
> fruit is 'apples'
> fruit is 'oranges'
> fruit is 'lemons'
> fruit is 'pears'
DO NOT ADD OR DELETE ELEMENTS TO AN ARRAY BEING PROCESSED IN A FOREACH LOOP.
my @numbers = qw (zero one two three);
foreach my $num (@numbers)
{
shift(@numbers) if($num eq 'one');
print "num is '$num'\n";
}
> num is 'zero'
> num is 'one'
> num is 'three'
# note: I deleted 'zero', but I failed to
# print out 'two', which is still part of array.
# BAD!!
VAR acts as an alias to the element of the array itself. Changes to VAR propagate to changing the array.
my @integers = ( 23, 142, 9384, 83948 );
foreach my $num (@integers)
{ $num+=100; }
print Dumper \@integers;
> $VAR1 = [
> 123,
> 242,
> 9484,
> 84048
> ];
Use sort() to sort an array alphabetically. The return value is the sorted version of the array. The array passed in is left untouched.
my @fruit = qw ( pears apples bananas oranges );
my @sorted_array = sort(@fruit);
print Dumper \@sorted_array ;
>$VAR1 = [
> 'apples',
> 'bananas',
> 'oranges',
> 'pears'
> ];
Sorting a list of numbers will sort them alphabetically as well, which probably is not what you want.
my @scores = ( 1000, 13, 27, 200, 76, 150 );
my @sorted_array = sort(@scores);
print Dumper \@sorted_array ;
> $VAR1 = [
> 1000, # 1's
> 13, # 1's
> 150, # 1's
> 200,
> 27,
> 76
> ];
The sort() function can also take a code block ( any piece of code between curly braces ) which defines how to perform the sort if given any two elements from the array. The code block uses two global variables, $a and $b, and defines how to compare the two entries.
This is how you would sort an array numerically.
my @scores = ( 1000, 13, 27, 200, 76, 150 );
my @sorted_array = sort {$a<=>$b} (@scores);
print Dumper \@sorted_array ;
> $VAR1 = [
> 13,
> 27,
> 76,
> 150,
> 200,
> 1000
> ];
The reverse() function takes a list and returns an array in reverse order. The last element becomes the first element. The first element becomes the last element.
my @numbers = reverse (1000,13,27,200,76,150);
print Dumper \@numbers ;
> $VAR1 = [
> 150,
> 76,
> 200,
> 27,
> 13,
> 1000
> ];
Use splice() to add or remove elements into or out of any index range of an array.
splice ( ARRAY , OFFSET , LENGTH , LIST );
The elements in ARRAY starting at OFFSET and going for LENGTH indexes will be removed from ARRAY. Any elements from LIST will be inserted at OFFSET into ARRAY.
my @words = qw ( hello there );
splice(@words, 1, 0, 'out');
warn join(" ", @words);
> hello out there ...
An array is initialized as having no entries. Therefore you can test to see if an array is initialized by calling scalar() on it. This is equivalent to calling defined() on a scalar variable. If scalar() returns false (i.e. integer 0), then the array is uninitialized.
If you want to uninitialize an array that contains data, then you do NOT want to assign it undef like you would a scalar. This would fill the array with one element at index zero with a value of undefined.
my @array = undef; # WRONG
To clear an array to its original uninitialized state, assign an empty list to it. This will clear out any entries, and leave you with a completely empty array.
my @array = (); # RIGHT
Hashes are preceded with a percent sign sigil.
The "%" is a stylized "key/value" pair.
A hash stores a bunch of scalars that are accessed via a string index called a "key"
Perl hashes are ONE-DIMENSIONAL ONLY. (Do Not Panic.)
There is no order to the elements in a hash. (Well, there is, but you should not use a hash with an assumption about what order the data will come out.)
You can assign any even number of scalars to a hash. Perl will extract them in pairs. The first item will be treated as the key, and the second item will be treated as the value.
When you refer to an entire hash, use the "%" sigil.
my %info = qw ( name John age 42 );
When you look up a key in the hash, the "%" character changes to a "$"
my %info = qw ( name John age 42 );
my $data = $info{name};
warn $data;
> John ...
The keys of a hash are not pre-declared. If the key does not exist during an ASSIGNMENT, the key is created and given the assigned value.
my %inventory;
$inventory{apples}=42;
$inventory{pears}=17;
$inventory{bananas}=5;
print Dumper \%inventory;
>$VAR1 = {
> 'bananas' => 5,
> 'apples' => 42,
> 'pears' => 17
> };
If the key does not exist during a FETCH, the key is NOT created, and undef is returned.
my %inventory;
$inventory{apples}=42;
my $peaches = $inventory{peaches};
warn "peaches is '$peaches'";
print Dumper \%inventory;
> Use of uninitialized value in concatenation
> peaches is '' at ./test.pl line 13.
> $VAR1 = {
> 'apples' => 42
> };
Use exists() to see if a key exists in a hash. You cannot simply test the value of a key, since a key might exist but store a value of FALSE
my %pets = ( cats=>2, dogs=>1 );
unless(exists($pets{fish}))
{ print "No fish here\n"; }
Warning: during multi-key lookup, all the lower level keys are autovivified, and only the last key has exists() tested on it. This only happens if you have a hash of hash references. References are covered later, but this is a "feature" specific to exists() that can lead to very subtle bugs. Note in the following example, we explicitely create the key "Florida", but we only test for the existence of {Maine}->{StateBird}, which has the side effect of creating the key {Maine} in the hash.
my %stateinfo;
$stateinfo{Florida}->{Abbreviation}='FL';
if (exists($stateinfo{Maine}->{StateBird}))
{ warn "it exists"; }
print Dumper \%stateinfo;
> $VAR1 = {
> 'Florida' => {
> 'Abbreviation' => 'FL'
> },
> 'Maine' => {}
> };
You must test each level of key individually, and build your way up to the final key lookup if you do not want to autovivify the lower level keys.
my %stateinfo;
$stateinfo{Florida}->{Abbreviation}='FL';
if (exists($stateinfo{Maine}))
{
if (exists($stateinfo{Maine}->{StateBird}))
{ warn "it exists"; }
}
print Dumper \%stateinfo;
> $VAR1 = {
> 'Florida' => {
> 'Abbreviation' => 'FL'
> }
> };
Use delete to delete a key/value pair from a hash. Once a key is created in a hash, assigning undef to it will keep the key in the hash and will only assign the value to undef. The only way to remove a key/value pair from a hash is with delete().
my %pets =
(
fish=>3,
cats=>2,
dogs=>1,
);
$pets{cats}=undef;
delete($pets{fish});
print Dumper \%pets;
> $VAR1 = {
> 'cats' => undef,
> 'dogs' => 1
> };
Use keys() to return a list of all the keys in a hash. The order of the keys will be based on the internal hashing algorithm used, and should not be something your program depends upon. Note in the example below that the order of assignment is different from the order printed out.
my %pets =
(
fish=>3,
cats=>2,
dogs=>1,
);
foreach my $pet (keys(%pets))
{
print "pet is '$pet'\n";
}
> pet is 'cats'
> pet is 'dogs'
> pet is 'fish'
If the hash is very large, then you may wish to use the each() function described below.
Use values() to return a list of all the values in a hash. The order of the values will match the order of the keys return in keys().
my %pets =
(
fish=>3,
cats=>2,
dogs=>1,
);
my @pet_keys = keys(%pets);
my @pet_vals = values(%pets);
print Dumper \@pet_keys;
print Dumper \@pet_vals;
> $VAR1 = [
> 'cats',
> 'dogs',
> 'fish'
> ];
> $VAR1 = [
> 2,
> 1,
> 3
> ];
If the hash is very large, then you may wish to use the each() function described below.
Use each() to iterate through each key/value pair in a hash, one at a time.
my %pets =
(
fish=>3,
cats=>2,
dogs=>1,
);
while(my($pet,$qty)=each(%pets))
{
print "pet='$pet', qty='$qty'\n";
}
> pet='cats', qty='2'
> pet='dogs', qty='1'
> pet='fish', qty='3'
Every call to each() returns the next key/value pair in the hash. After the last key/value pair is returned, the next call to each() will return an empty list, which is boolean false. This is how the while loop is able to loop through each key/value and then exit when done.
Every hash has one "each iterator" attached to it. This iterator is used by perl to remember where it is in the hash for the next call to each().
Calling keys() on the hash will reset the iterator. The list returned by keys() can be discared.
keys(%hash);
Do not add keys while iterating a hash with each().
You can delete keys while iterating a hash with each().
The each() function does not have to be used inside a while loop. This example uses a subroutine to call each() once and print out the result. The subroutine is called multiple times without using a while() loop.
my %pets =
(
fish=>3,
cats=>2,
dogs=>1,
);
sub one_time
{
my($pet,$qty)=each(%pets);
# if key is not defined,
# then each() must have hit end of hash
if(defined($pet))
{ print "pet='$pet', qty='$qty'\n"; }
else
{ print "end of hash\n"; }
}
one_time; # cats
one_time; # dogs
keys(%pets); # reset the hash iterator
one_time; # cats
one_time; # dogs
one_time; # fish
one_time; # end of hash
one_time; # cats
one_time; # dogs
> pet='cats', qty='2'
> pet='dogs', qty='1'
> pet='cats', qty='2'
> pet='dogs', qty='1'
> pet='fish', qty='3'
> end of hash
> pet='cats', qty='2'
> pet='dogs', qty='1'
There is only one iterator variable connected with each hash, which means calling each() on a hash in a loop that then calls each() on the same hash another loop will cause problems. The example below goes through the %pets hash and attempts to compare the quantity of different pets and print out their comparison.
my %pets =
(
fish=>3,
cats=>2,
dogs=>1,
);
while(my($orig_pet,$orig_qty)=each(%pets))
{
while(my($cmp_pet,$cmp_qty)=each(%pets))
{
if($orig_qty>$cmp_qty)
{
print "there are more $orig_pet "
."than $cmp_pet\n";
}
else
{
print "there are less $orig_pet "
."than $cmp_pet\n";
}
}
}
> there are more cats than dogs
> there are less cats than fish
> there are more cats than dogs
> there are less cats than fish
> there are more cats than dogs
> there are less cats than fish
> there are more cats than dogs
> there are less cats than fish
> ...
The outside loop calls each() and gets "cats". The inside loop calls each() and gets "dogs". The inside loop continues, calls each() again, and gets "fish". The inside loop calls each() one more time and gets an empty list. The inside loop exits.
The outside loop calls each() which continues where the inside loop left off, namely at the end of the list, and returns "cats". The code then enters the inside loop, and the process repeats itself indefinitely.
One solution for this each() limitation is shown below. The inner loop continues to call each() until it gets the key that matches the outer loop key. The inner loop must skip the end of the hash (an undefined key) and continue the inner loop. This also fixes a problem in the above example in that we probably do not want to compare a key to itself.
my %pets =
(
fish=>3,
cats=>2,
dogs=>1,
);
while(my($orig_pet,$orig_qty)=each(%pets))
{
while(1)
{
my($cmp_pet,$cmp_qty)=each(%pets);
next unless(defined($cmp_pet));
last if($cmp_pet eq $orig_pet);
if($orig_qty>$cmp_qty)
{
print "there are more $orig_pet "
."than $cmp_pet\n";
}
else
{
print "there are less $orig_pet "
."than $cmp_pet\n";
}
}
}
> there are more cats than dogs
> there are less cats than fish
> there are less dogs than fish
> there are less dogs than cats
> there are more fish than cats
> there are more fish than dogs
If you do not know the outer loop key, either because its in someone else's code and they do not pass it to you, or some similar problem, then the only other solution is to call keys() on the hash for all inner loops, store the keys in an array, and loop through the array of keys using foreach. The inner loop will then not rely on the internal hash iterator value.
List context is a concept built into the grammar of perl. You cannot declare a "list context" in perl the way you might declare an @array or %hash. List context affects how perl executes your source code. Here is an example.
my @cart1=qw( milk bread butter);
my @cart2=qw( eggs bacon juice );
my @checkout_counter = ( @cart1, @cart2 );
print Dumper \@checkout_counter;
> $VAR1 = [
> 'milk',
> 'bread',
> 'butter',
> 'eggs',
> 'bacon',
> 'juice'
> ];
Basically, two people with grocery carts, @cart1 and @cart2, pulled up to the @checkout_counter and unloaded their carts without putting one of those separator bars in between them. The person behind the @checkout_counter has no idea whose groceries are whose.
Everything in list context gets reduced to an ordered series of scalars. The original container that held the scalars is forgotten.
In the above example the order of scalars is retained: milk, bread, butter is the order of scalars in @cart1 and the order of the scalars at the beginning of @checkout_counter. However, looking at just @checkout_counter, there is no way to know where the contents of @cart1 end and the contents of @cart2 begin. In fact, @cart1 might have been empty, and all the contents of @checkout_counter could belong to @cart2, but there is no way to know.
Sometimes, list context can be extremely handy. We have used list context repeatedly to initialize arrays and hashes and it worked as we would intuitively expect:
my %pets = ( fish=>3, cats=>2, dogs=>1 );
my @cart1 = qw( milk bread eggs);
The initial values for the hash get converted into an ordered list of scalars
( 'fish', 3, 'cats', 2, 'dogs', 1 )
These scalars are then used in list context to initialize the hash, using the first scalar as a key and the following scalar as its value, and so on throughout the list.
List context applies anytime data is passed around in perl. Scalars, arrays, and hashes are all affected by list context. In the example below, @house is intended to contain a list of all the items in the house. However, because the %pets hash was reduced to scalars in list context, the values 3,2,1 are disassociated from their keys. The @house variable is not very useful.
my %pets = ( fish=>3, cats=>2, dogs=>1 );
my @refridgerator=qw(milk bread eggs);
my @house=('couch',%pets,@refridgerator,'chair');
print Dumper \@house;
>$VAR1 = [
> 'couch',
> 'cats',
> 2,
> 'dogs',
> 1,
> 'fish',
> 3,
> 'milk',
> 'bread',
> 'eggs',
> 'chair'
> ];
There are times when list context on a hash does make sense.
my %encrypt=(tank=>'turtle',bomber=>'eagle');
my %decrypt=reverse(%encrypt) ;
print Dumper \%decrypt;
> $VAR1 = {
> 'eagle' => 'bomber',
> 'turtle' => 'tank'
> };
The %encrypt hash contains a hash look up to encrypt plaintext into cyphertext. Anytime you want to use the word "bomber", you actually send the word "eagle". The decryption is the opposite. Anytime you receive the word "eagle" you need to translate that to the word "bomber".
Using the %encrypt hash to perform decryption would require a loop that called each() on the %encrypt hash, looping until it found the value that matched the word received over the radio. This could take too long.
Instead, because there is no overlap between keys and values, (two different words dont encrypt to the same word), we can simply treat the %encrypt hash as a list, call the array reverse() function on it, which flips the list around from end to end, and then store that reversed list into a %decrypt hash.
References are a thing that refer (point) to something else.
The "something else" is called the "referent", the thing being pointed to.
Taking a reference and using it to access the referent is called "dereferencing".
A good real-world example is a driver's license. Your license "points" to where you live because it lists your home address. Your license is a "reference". The "referent" is your home. And if you have forgotten where you live, you can take your license and "dereferencing" it to get yourself home.
It is possible that you have roommates, which would mean multiple references exist to point to the same home. But there can only be one home per address.
In perl, references are stored in scalars. You can create a reference by creating some data (scalar, array, hash) and putting a "\" in front of it.
my %home=
(
fish=>3,cats=>2,dogs=>1,
milk=>1,bread=>2,eggs=>12,
);
my $license_for_alice = \%home;
my $license_for_bob = \%home;
Alice and Bob are roommates and their licenses are references to the same %home. This means that Alice could bring in a bunch of new pets and Bob could eat the bread out of the refridgerator even though Alice might have been the one to put it there. To do this, Alice and Bob need to dereference their licenses and get into the original %home hash.
$ {$license_for_alice} {dogs} += 5;
delete($ {$license_for_bob} {milk});
print Dumper \%home;
> $VAR1 = {
> 'eggs' => 12,
> 'cats' => 2,
> 'bread' => 2,
> 'dogs' => 6,
> 'fish' => 3
> };
A referent is any original data structure: a scalar, array, or hash. Below, we declare some named referents: age, colors, and pets.
my $age = 42;
my @colors = qw( red green blue );
my %pets=(fish=>3,cats=>2,dogs=>1);
A reference points to the referent. To take a reference to a named referent, put a "\" in front of the named referent.
my $ref_to_age = \$age;
my $r_2_colors = \@colors;
my $r_pets = \%pets;
To dereference, place the reference in curly braces and prefix it with the sigil of the appropriate type. This will give access to the entire original referent.
${$ref_to_age}++; # happy birthday
pop(@{$r_2_colors});
my %copy_of_pets = %{$r_pets};
print "age is '$age'\n";
> age is '43'
If there is no ambiguity in dereferencing, the curly braces are not needed.
$$ref_to_age ++; # another birthday
print "age is '$age'\n";
> age is '44'
It is also possible to dereference into an array or hash with a specific index or key.
my @colors = qw( red green blue );
my %pets=(fish=>3,cats=>2,dogs=>1);
my $r_colors = \@colors; my $r_pets = \%pets;
${$r_pets} {dogs} += 5;
${$r_colors}[1] = 'yellow';
print Dumper \@colors; print Dumper \%pets;
> $VAR1 = [
'red',
'yellow',
'blue'
];
$VAR1 = {
'cats' => 2,
'dogs' => 6,
'fish' => 3
};
Because array and hash referents are so common, perl has a shorthand notation for indexing into an array or looking up a key in a hash using a reference. Take the reference, follow it by "->", and then follow that by either "[index]" or "{key}".
This:
${$r_pets} {dogs} += 5;
${$r_colors}[1] = 'yellow';
is exactly the same as this:
$r_pets->{dogs} += 5;
$r_colors->[1] = 'yellow';
Here are some referents named age, colors, and pets. Each named referent has a reference to it as well.
my $age = 42;
my @colors = qw( red green blue );
my %pets=(fish=>3,cats=>2,dogs=>1);
my $r_age = \$age;
my $r_colors = \@colors;
my $r_pets = \%pets;
It is also possible in perl to create an ANONYMOUS REFERENT. An anonymous referent has no name for the underlying data structure and can only be accessed through the reference.
To create an anonymous array referent, put the contents of the array in square brackets. The square brackets will create the underlying array with no name, and return a reference to that unnamed array.
my $colors_ref = [ 'red', 'green', 'blue' ];
print Dumper $colors_ref;
> $VAR1 = [
> 'red',
> 'green',
> 'blue'
> ];
To create an anonymous hash referent, put the contents of the hash in square brackets. The square brackets will create the underlying hash with no name, and return a reference to that unnamed hash.
my $pets_ref = { fish=>3,cats=>2,dogs=>1 };
print Dumper $pets_ref;
> $VAR1 = {
> 'cats' => 2,
> 'dogs' => 1,
> 'fish' => 3
> };
Note that $colors_ref is a reference to an array, but that array has no name to directly access its data. You must use $colors_ref to access the data in the array.
Likewise, $pets_ref is a reference to a hash, but that hash has no name to directly access its data. You must use $pets_ref to access the data in the hash.
Arrays and hashes can only store scalar values. But because scalars can hold references, complex data structures are now possible. Using references is one way to avoid the problems associated with list context. Here is another look at the house example, but now using references.
my %pets = ( fish=>3, cats=>2, dogs=>1 );
my @refridgerator=qw(milk bread eggs);
my $house={
pets=>\%pets,
refridgerator=>\@refridgerator
};
print Dumper $house;
> $VAR1 = {
> 'pets' => {
> 'cats' => 2,
> 'dogs' => 1,
> 'fish' => 3
> },
> 'refridgerator' => [
> 'milk',
> 'bread',
> 'eggs'
> ]
> };
The $house variable is a reference to an anonymous hash, which contains two keys, "pets" and "refridgerator". These keys are associated with values that are references as well, one a hash reference and the other an array reference.
Dereferencing a complex data structure can be done with the arrow notation or by enclosing the reference in curly braces and prefixing it with the appropriate sigil.
# Alice added more canines
$house->{pets}->{dogs}+=5;
# Bob drank all the milk
shift(@{$house->{refridgerator}});
Perl autovivifies any structure needed when assigning or fetching from a reference. The autovivified referents are anonymous. Perl will assume you know what you are doing with your structures. In the example below, we start out with an undefined scalar called $scal. We then fetch from this undefined scalar, as if it were a reference to an array of a hash of an array of a hash of an array. Perl autovivifies everything under the assumption that that is what you wanted to do.
my $scal;
my $val =
$scal->[2]->{somekey}->[1]->{otherkey}->[1];
print Dumper $scal;
> $VAR1 = [
> undef,
> ${\$VAR1->[0]},
> {
> 'somekey' => [
> ${\$VAR1->[0]},
> {
> 'otherkey' => []
> }
> ]
> }
> ];
Perl implements multidimensional arrays using one-dimensional arrays and references.
my $mda;
for(my $i=0;$i<2;$i++)
{
for(my $j=0;$j<2;$j++)
{
for(my $k=0;$k<2;$k++)
{
$mda->[$i]->[$j]->[$k] =
"row=$i, col=$j, depth=$k";
}
}
}
print Dumper $mda;
> $VAR1 = [
> [
> [
> 'row=0, col=0, depth=0',
> 'row=0, col=0, depth=1'
> ],
> [
> 'row=0, col=1, depth=0',
> 'row=0, col=1, depth=1'
> ]
> ],
> [
> [
> 'row=1, col=0, depth=0',
> 'row=1, col=0, depth=1'
> ],
> [
> 'row=1, col=1, depth=0',
> 'row=1, col=1, depth=1'
> ]
> ]
> ];
Perl will stringify a reference if you try to do anything string-like with it, such as print it.
my $referent = 42;
my $reference = \$referent;
warn "reference is '$reference'";
> reference is 'SCALAR(0x812e6ec)'
But perl will not allow you to create a string and attempt to turn it into a reference.
my $reference = 'SCALAR(0x812e6ec)';
my $value = $$reference;
> Can't use string ("SCALAR(0x812e6ec)") as
> a SCALAR ref while "strict refs" in use
Turning strict off only gives you undef.
no strict;
my $reference = 'SCALAR(0x812e6ec)';
my $value = $$reference;
warn "value not defined" unless(defined($value));
warn "value is '$value'\n";
> value not defined
> Use of uninitialized value in concatenation
Because a reference is always a string that looks something like "SCALAR(0x812e6ec)", it will evaluate true when treated as a boolean, even if the value to which it points is false.
The ref() function takes a scalar and returns a string indicating what kind of referent the scalar is referencing. If the scalar is not a reference, ref() returns false (an empty string).
my $temp = \42;
my $string = ref($temp);
warn "string is '$string'";
> string is 'SCALAR'
Here we call ref() on several types of variable:
sub what_is_it
{
my ($scalar)=@_;
my $string = ref($scalar);
print "string is '$string'\n";
}
what_is_it( \'hello' );
what_is_it( [1,2,3] );
what_is_it( {cats=>2} );
what_is_it( 42 );
> string is 'SCALAR'
> string is 'ARRAY'
> string is 'HASH'
> string is ''
Note that this is like stringification of a reference except without the address being part of the string. Instead of SCALAR(0x812e6ec), its just SCALAR. Also note that if you stringify a non-reference, you get the scalar value. But if you call ref() on a non-reference, you get an empty string, which is always false.
Standard statements get executed in sequential order in perl.
my $name = 'John Smith';
my $greeting = "Hello, $name\n";
print $greeting;
Control flow statements allow you to alter the order of execution as the program is running.
if( $price == 0 )
{
print "Free Beer!\n";
}
Perl supports the following control flow structures:
#
# LABEL is an optional name that identifies the
# control flow structure. It is a bareword identifier
# followed by a colon. example==> MY_NAME:
#
# BLOCK ==> zero or more statements contained
# in curly braces { print "hi"; }
LABEL BLOCK
LABEL BLOCK continue BLOCK
# BOOL ==> boolean (see boolean section above)
if (BOOL) BLOCK
if (BOOL) BLOCK else BLOCK
if (BOOL) BLOCK elsif (BOOL) BLOCK elsif ()...
if (BOOL) BLOCK elsif (BOOL) BLOCK ... else BLOCK
unless (BOOL) BLOCK
unless (BOOL) BLOCK else BLOCK
unless (BOOL) BLOCK elsif (BOOL) BLOCK elsif ()...
unless (BOOL) BLOCK elsif (BOOL) BLOCK ... else BLOCK
LABEL while (BOOL) BLOCK
LABEL while (BOOL) BLOCK continue BLOCK
LABEL until (BOOL) BLOCK
LABEL until (BOOL) BLOCK continue BLOCK
# INIT, TEST, CONT are all expressions
# INIT is an initialization expression
# INIT is evaluated once prior to loop entry
# TEST is BOOLEAN expression that controls loop exit
# TEST is evaluated each time after BLOCK is executed
# CONT is a continuation expression
# CONT is evaluated each time TEST is evaluated TRUE
LABEL for ( INIT; TEST; CONT ) BLOCK
# LIST is a list of scalars,
# see arrays and list context sections later in text
LABEL foreach (LIST) BLOCK
LABEL foreach VAR (LIST) BLOCK
LABEL foreach VAR (LIST) BLOCK continue BLOCK
Labels are always optional. A label is an identifier followed by a colon.
A label is used to give its associated control flow structure a name.
Inside a BLOCK of a control flow structure, you can call
next;
last;
redo;
If the structure has a LABEL, you can call
next LABEL;
last LABEL;
redo LABEL;
If no label is given to next, last, or redo, then the command will operate on the inner-most control structure. If a label is given, then the command will operate on the control structure given.
The last command goes to the end of the entire control structure. It does not execute any continue block if one exists.
The next command skips the remaining BLOCK. if there is a continue block, execution resumes there. After the continue block finishes, or if no continue block exists, execution starts the next iteration of the control construct if it is a loop construct.
The redo command skips the remaining BLOCK. It does not execute any continue block (even if it exists). Execution then resumes at the start of the control structure without evaluating the conditional again.
Perl has a package declaration statement that looks like this:
package NAMESPACE;
This package declaration indicates that the rest of the enclosing block, subroutine, eval, or file belongs to the namespace given by NAMESPACE.
The standard warnings, strictness, and Data::Dumper are attached to the namespace in which they were turned on with "use warnings;" etc. Anytime you declare a new package namespace, you will want to "use" these again.
package SomeOtherPackage;
use warnings; use strict; use Data::Dumper;
All perl scripts start with an implied declaration of:
package main;
You can access package variables with the appropriate sigil, followed by the package name, followed by a double colon, followed by the variable name. This is called a "package QUALIFIED" variable where the package name is explicitely stated.
$package_this::age;
@other_package::refridgerator;
%package_that::pets;
If you use an UNQUALIFIED variable in your code, perl assumes it is in the the most recently declared package namespace that was declared.
When you have strict-ness turned on, there are two ways to create and use package variables:
1) Use the fully package qualified name everywhere in your code:
# can use variable without declaring it with 'my'
$some_package::answer=42;
warn "The value is '$some_package::answer'\n";
2) Use "our" to declare the variable.
package this_package;
our $name='John';
warn "name is '$name'";
Using "our" is the preferred method. You must have perl 5.6.0 or later for "our" declarations.
The difference between the two methods is that always using package qualified variable names means you do NOT have to declare the package you are in. You can create variables in ANY namespace you want, without ever having to declare the namespace explicitely. You can even declare variables in someone else's package namespace. There is no restrictions in perl that prevent you from doing this.
To encourage programmers to play nice with each other's namespaces, the "our" function was created. Declaring a variable with "our" will create the variable in the current namespace. If the namespace is other than "main", then you will need to declare the package namespace explicitely. However, once a package variable is declared with "our", the fully package qualified name is NOT required, and you can refer to the variable just on its variable name, as example (2) above refers to the $name package variable.
We could also access the Hogs variables using a fully package qualified name. We do not HAVE to use the "our" shortcut even if we used it to declare it. The "our" declaration is a shorthand for declaring a package variable. Once the package variable exists, we can access it any way we wish.
package Hogs;
our $speak = 'oink';
print "Hogs::speak is '$Hogs::speak'\n";
> Hogs::speak is 'oink'
When you declare a package inside a code block, that package namespace declaration remains in effect until the end of the block, at which time, the package namespace reverts to the previous namespace.
package Hogs;
our $speak = 'oink';
{ # START OF CODE BLOCK
package Heifers;
our $speak = 'moo';
} # END OF CODE BLOCK
print "speak is '$speak'\n";
> speak is 'oink'
The Heifers namespace still exists, as does all the variables that were declared in that namespace. Its just that outside the code block, the "our Heifers;" declaration has worn off, and we now have to use a fully package qualified name to get to the variables in Heifers package. This "wearing off" is a function of the code block being a "lexical scope" and a package declaration only lasts to the end of the current lexical scope.
The package variables declared inside the code block SURVIVE after the code block ends.
{
package Heifers;
our $speak = 'moo';
}
print "Heifers::speak is '$Heifers::speak'\n";
> Heifers::speak is 'moo'
Lexical refers to words or text. A lexical scope exists while execution takes place inside of a particular chunk of source code. In the above examples, the "package Heifers;" only exists inside the curly braces of the source code. Outside those curly braces, the package declaration has gone out of scope, which is a technical way of saying its "worn off".
Scope refers to vision, as in telescope. Within a lexical scope, things that have lexical limitations (such as a package declaration) are only "visible" inside that lexical space.
So "lexical scope" refers to anything that is visible or has an effect only withing a certain boundary of the source text or source code. The easiest way to demonstrate lexical scoping is lexical variables, and to show how lexical variables differ from "our" variables.
Lexical variables declared inside a lexical scope do not survive outside the lexical scope.
no warnings;
no strict;
{
my $speak = 'moo';
}
warn "speak is '$speak'\n";
> speak is ''
The lexical variable "$speak" goes out of scope at the end of the code block (at the "}" character), so it does not exist when we try to print it out after the block. We had to turn warnings and strict off just to get it to compile because with warnings and strict on, perl will know $speak does not exist when you attempt to print it, so it will throw an exception and quit.
Lexically scoped variables have three main features:
1) Lexical variables do not belong to any package namespace, so you cannot prefix them with a package name:
no warnings;
package main;
my $cnt='I am just a lexical';
warn "main::cnt is '$main::cnt'";
> main::cnt is ''
2) Lexical variables are only directly accessible from the point where they are declared to the end of the nearest enclosing block, subroutine, eval, or file.
no strict;
{
my $some_lex = 'I am lex';
}
warn "some_lex is '$some_lex'";
> some_lex is ''
3) Lexical variables are subject to "garbage collection" at the end of scope. If nothing is using a lexical variable at the end of scope, perl will remove it from its memory. Every time a variable is declared with "my", it is created dynamically, during execution. The location of the variable will change each time. Note in the example below, we create a new $lex_var each time through the loop, and $lex_var is at a different address each time.
my @cupboard;
for (1 .. 5)
{
my $lex_var = 'canned goods';
my $lex_ref = \$lex_var;
push(@cupboard, $lex_ref);
print "$lex_ref\n";
}
> SCALAR(0x812e770)
> SCALAR(0x812e6c8)
> SCALAR(0x812e6e0)
> SCALAR(0x81624c8)
> SCALAR(0x814cf64)
Lexical variables are just plain good. They generally keep you from stepping on someone else's toes. They also keep your data more private than a package variable. Package variables are permanent, never go out of scope, never get garbage collected, and are accessible from anyone's script.
When a lexical variable goes out of scope, perl will check to see if anyone is using that variable, and if no one is using it, perl will delete that variable and free up memory.
The freed up memory is not returned to the system, rather the freed up memory is used for possible declarations of new lexically scoped variables that could be declared later in the program.
This means that your program will never get smaller because of lexical variables going of of scope. Once the memory is allocated for perl, it remains under perl's jurisdiction. But perl can use garbage collected space for other lexical variables.
If a lexical variable is a referent to another variable, then the lexical will not be garbage collected when it goes out of scope.
no strict;
my $referring_var;
{
my $some_lex = 'I am lex';
$referring_var=\$some_lex;
}
warn "some_lex is '$some_lex'";
warn "referring var refers to '$$referring_var'";
> some_lex is ''
> referring var refers to 'I am lex'
When the lexical $some_lex went out of scope, we could no longer access it directly. But since $referring_var is a reference to $some_lex, then $some_lex was never garbage collected, and it retained its value of "I am lex". The data in $some_lex was still accessible through referring_var.
Perl uses reference count based garbage collection. It is rudimentary reference counting, so circular references will not get collected even if nothing points to the circle. The example below shows two variables that refer to each other but nothing refers to the two variables. Perl will not garbage collect these variables even though they are completely inaccessible by the end of the code block.
{
my ($first,$last);
($first,$last)=(\$last,\$first);
}
Garbage collection does not rely strictly on references to a variable to determine if it should be garbage collected. If a subroutine uses a lexical variable, then that variable will not be garbage collected as long as the subroutine exists.
Subroutines that use a lexical variable declared outside of the subroutine declaration are called "CLOSURES".
In the example below, the lexical variable, $cnt, is declared inside a code block and would normally get garbage collected at the end of the block. However, two subroutines are declared in that same code block that use $cnt, so $cnt is not garbage collected. Since $cnt goes out of scope, the only things that can access it after the code block are the subroutines. Note that a reference to $cnt is never taken, however perl knows that $cnt is needed by the subroutines and therefore keeps it around.
{
my $cnt=0;
sub inc{$cnt++; print "cnt is '$cnt'\n";}
sub dec{$cnt--; print "cnt is '$cnt'\n";}
}
inc;
inc;
inc;
dec;
dec;
inc;
> cnt is '1'
> cnt is '2'
> cnt is '3'
> cnt is '2'
> cnt is '1'
> cnt is '2'
Subroutine names are like names of package variables. The subroutine gets placed in the current declared package namespace. Therefore, named subroutines are like package variables in that, once declared, they never go out of scope or get garbage collected.
Package variables are not evil, they are just global variables, and they inherit all the possible problems associated with using global variables in your code.
In the event you DO end up using a package variable in your code, they do have some advantages. They are global, which means they can be a convenient way for several different blocks of perl code to talk amongst themselves using an agreed upon global variable as their channel.
Imagine several subroutines across several files that all want to check a global variable: $Development::Verbose. If this variable is true, these subroutines print detailed information. If it is false, these subroutines print little or no information.
package Development;
our $Verbose=1;
sub Compile {
if ($Development::Verbose)
{ print "compiling\n"; } }
sub Link {
if ($Development::Verbose)
{ print "linking\n"; } }
sub Run {
if ($Development::Verbose)
{ print "running\n"; } }
Compile;
Link;
Run;
> compiling
> linking
> running
The three subroutines could be in different files, in different package namespaces, and they could all access the $Development::Verbose variable and act accordingly.
When working with global variables, there are times when you want to save the current value of the global variable, set it to a new and temporary value, execute some foreign code that will access this global, and then set the global back to what it was.
Continuing the previous example, say we wish to create a RunSilent subroutine that stores $Development::Verbose in a temp variable, calls the original Run routine, and then sets $Development::Verbose back to its original value.
package Development;
our $Verbose=1;
sub Compile {
if ($Development::Verbose)
{ print "compiling\n"; } }
sub Link {
if ($Development::Verbose)
{ print "linking\n"; } }
sub Run {
if ($Development::Verbose)
{ print "running\n"; } }
sub RunSilent {
my $temp = $Development::Verbose;
$Development::Verbose=0;
Run;
$Development::Verbose=$temp; }
Compile;
Link;
RunSilent;
> compiling
> linking
This can also be accomplished with the "local()" function. The local function takes a package variable, saves off the original value, allows you to assign a temp value to it. That new value is seen by anyone accessing the variable. And at the end of the lexical scope in which local() was called, the original value for the variable is returned.
The RunSilent subroutine could be written like this:
sub RunSilent {
local($Development::Verbose)=0;
Run; }
Perl originally started with nothing but package variables. The "my" lexical variables were not introduced until perl version 4. So to deal with all the package variables, perl was given the local() function. Local is also a good way to create a temporary variable and make sure you dont step on someone else's variable of the same name.
Perl allows you to declare named subroutines and anonymous subroutines, similar to the way you can declare named variables and anonymous variables.
Subroutines use the ampersand ( & ) as their sigil. But while the sigils for scalars, arrays, and hashes are mandatory, the sigil for subroutines is optional.
Below is the named subroutine declaration syntax:
sub NAME BLOCK
NAME can be any valid perl identifier.
BLOCK is a code block enclosed in parenthesis.
The NAME of the subroutine is placed in the current package namespace, in the same way "our" variables go into the current package namespace. So once a named subroutine is declared, you may access it with just NAME if you are in the correct package, or with a fully package qualified name if you are outside the package. And you can use the optional ampersand sigil in either case.
package MyArea;
sub Ping {print "ping\n";}
Ping;
&Ping;
MyArea::Ping;
&MyArea::Ping;
> ping
> ping
> ping
> ping
Once the current package declaration changes, you MUST use a fully package qualified subroutine name to call the subroutine.
package MyArea;
sub Ping {print "ping\n";}
package YourArea;
MyArea::Ping;
&MyArea::Ping;
&Ping; # error, looking in current package YourArea
> ping
> ping
> Undefined subroutine &YourArea::Ping
Below is the anonymous subroutine declaration syntax:
sub BLOCK
This will return a code reference, similar to how [] returns an array reference, and similar to how {} returns a hash reference.
sub what_is_it
{
my ($scalar)=@_;
my $string = ref($scalar);
print "ref returned '$string'\n";
}
my $temp = sub {print "Hello\n";};
what_is_it($temp);
> ref returned 'CODE'
The contents of the code block are invisible to anything outside the code block. For this reason, things like Data::Dumper cannot look inside the code block and show you the actual code. Instead it does not even try and just gives you a place holder that returns a dummy string.
my $temp = sub {print "Hello\n";};
print Dumper $temp;
> $VAR1 = sub { "DUMMY" };
Any values you want to pass to a subroutine get put in the parenthesis at the subroutine call. For normal subroutines, all arguments go through the list context crushing machine and get reduced to a list of scalars. The original containers are not known inside the subroutine. The subroutine will not know if the list of scalars it recieves came from scalars, arrays, or hashes.
To avoid some of the list context crushing, a subroutine can be declared with a prototype, which are discussed later.
Inside the subroutine, the arguments are accessed via a special array called @_, since all the arguments passed in were reduced to list context, these arguments fit nicely into an array. The @_ array can be processed just like any other regular array. If the arguments are fixed and known, the preferred way to extract them is to assign @_ to a list of scalars with meaningful names.
sub compare {
my ($left,$right)=@_;
return $left<=>$right;
}
The @_ array is "magical" in that it is really a list of aliases for the original arguments passed in. Therefore, assigning a value to an element in @_ will change the value in the original variable that was passed into the subroutine call. Subroutine parameters are effectively IN/OUT.
sub swap { (@_) = reverse(@_); }
my $one = "I am one";
my $two = "I am two";
swap($one,$two);
warn "one is '$one'";
warn "two is '$two'";
> one is 'I am two'
> two is 'I am one'
Assigning to the entire @_ array does not work, you have to assign to the individual elements. If swap were defined like this, the variables $one and $two would remain unchanged.
sub swap {
my ($left,$right)=@_;
@_ = ($right,$left);
}
Dereferencing a code reference causes the subroutine to be called. A code reference can be dereferenced by preceding it with an ampersand sigil or by using the arrow operator and parenthesis "->()". The preferred way is to use the arrow operator with parens.
my $temp = sub {print "Hello\n";};
&{$temp};
&$temp;
$temp->(); # preferred
> Hello
> Hello
> Hello
When calling a subroutine with the "&" sigil prefix and no parenthesis, the current @_ array gets implicitely passed to the subroutine being called. This can cause subtly odd behaviour if you are not expecting it.
sub second_level {
print Dumper \@_;
}
sub first_level {
# using '&' sigil and no parens.
# doesn't look like I'm passing any params
# but perl will pass @_ implicitely.
&second_level;
}
first_level(1,2,3);
> $VAR1 = [
> 1,
> 2,
> 3
> ];
This generally is not a problem with named subroutines because you probably will not use the "&" sigil. However, when using code referernces, dereferencing using the "&" may cause imlied arguments to be passed to the new subroutine. For this reason, the arrow operator is the preferred way to dereference a code reference.
$code_ref->(); # pass nothing, no implicit @_
$code_ref->(@_); # explicitly pass @_
$code_ref->( 'one', 'two' ); # pass new parameters
Subroutines can return a single value or a list of values. The return value can be explicit, or it can be implied to be the last statement of the subroutine. An explicit return statement is the preferred approach if any return value is desired.
# return a single scalar
sub ret_scal {
return "boo";
}
my $scal_var = ret_scal;
print Dumper \$scal_var;
# return a list of values
sub ret_arr {
return (1,2,3);
}
my @arr_var = ret_arr;
print Dumper \@arr_var;
> $VAR1 = \'boo';
> $VAR1 = [
> 1,
> 2,
> 3
> ];
The return value of a subroutine is often used within a boolean test. The problem is that the subroutine needs to know if it is called in scalar context or array context.
Returning a simple "undef" value (or 0 or 0.0 or "") will work in scalar context, but in array context, it will create an array with the first element set to undef. In boolean context, an array with one or more elements is considered true.
A return statement by itself will return undef in scalar context and an empty list in list context. This is the preferred way to return false in a subroutine.
sub this_is_false {
return; # undef or empty list
}
my $scal_var = this_is_false;
my @arr_var = this_is_false;
The caller() function can be used in a subroutine to find out information about where the subroutine was called from and how it was called. Caller takes one argument that indicates how far back in the call stack to get its information from. For information about the current subroutine, use caller(0).
sub HowWasICalled {
my @info = caller(0);
print Dumper \@info;
}
HowWasICalled;
>$VAR1 = [
> 'main',
> './test.pl',
> 13,
> 'main::HowWasICalled',
> 1,
> undef,
> undef,
> undef,
> 2,
> 'UUUUUUUUUUUU'
> ];
The caller() function returns a list of information in the following order
|
0 |
$package |
package namespace at time of call |
|
1 |
$filename |
filename where called occurred |
|
2 |
$line |
line number in file where call occurred |
|
3 |
$subroutine |
name of subroutine called |
|
4 |
$hasargs |
true if explicit arguments passed in |
|
5 |
$wantarray |
list=1, scalar=0, void=undef |
|
6 |
$evaltext |
evaluated text if an eval block |
|
7 |
$is_require |
true if created by "require" or "use" |
|
8 |
$hints |
internal use only, disregard |
|
9 |
$bitmask |
internal use only, disregard |
Note in the example above, I ran the code in a file called test.pl. The call occurred in package main, the default package namespace, and it occurred at line 13 of the file. The package qualified name of the subroutine that was called was main::HowWasICalled. The package qualified name must be given since you dont know what package is current where the subroutine was called from, that information is hidden in lexical scope.
The argument of interest is the $wantarray argument. This indicates what return value is expected of the subroutine from where it was called. The subroutine could have been called in void context meaning the return value is thrown away. Or it could have been called and the return value assigned to a scalar. Or it could have been called and the return value assigned to a list of scalars.
sub CheckMyWantArray
{
my @info = caller(0);
my $wantarray = $info[5];
$wantarray='undef'
unless(defined($wantarray));
print "wantarray is '$wantarray'\n";
}
CheckMyWantArray; # undef
my $scal = CheckMyWantArray; # 0
my @arr = CheckMyWantArray; # 1
> wantarray is 'undef'
> wantarray is '0'
> wantarray is '1'
You can use the wantarray variable from caller() to create a subroutine that is sensitive to the context in which it was called.
sub ArrayProcessor {
my @info = caller(0);
my $wantarray = $info[5];
return unless(defined($wantarray));
if($wantarray)
{ return @_; }
else
{ return scalar(@_); }
}
my @arr=qw(alpha bravo charlie);
ArrayProcessor(@arr);
my $scal = ArrayProcessor(@arr); # 3
my @ret_arr = ArrayProcessor(@arr); # alpha ...
print "scal is '$scal'\n";
print Dumper \@ret_arr;
> scal is '3'
>$VAR1 = [
> 'alpha',
> 'bravo',
> 'charlie'
> ];
When perl works on your source code, it will always be in one of two modes: compiling or interpreting. Perl has some hooks to allow access into these different cycles. They are code blocks that are prefixed with BEGIN, CHECK, INIT, and END.
Compiling: translating the source text into machine usable internal format.
Interpreting: executing the machine usable, internal format.
The BEGIN block is immediate.
BEGIN -> execute block as soon as it is compiled, even before compiling anything else.
The other blocks, including normal code, do not execute until after the entire program has been compiled. When anything other than a BEGIN block is encountered, they are compiled and scheduled for exeuction, but perl continues compiling the rest of the program.
CHECK -> Schedule these blocks for execution after all source code has been compiled.
INIT-> Schedule these blocks for execution after the CHECK blocks have executed.
normal code -> Schedule normal code to execute after all INIT blocks.
END -> Schedule for execution after normal code has completed.
Multiple BEGIN blocks are executed immediately in NORMAL declaration order.
Multiple CHECK blocks are scheduled to execute in REVERSE declaration order.
Multiple INIT blocks are scheduled to execute in NORMAL declaration order.
Multiple ENDblocks are scheduled to execute in REVERSE declaration order.
END { print "END 1\n" }
CHECK { print "CHECK 1\n" }
BEGIN { print "BEGIN 1\n" }
INIT { print "INIT 1\n" }
print "normal\n";
INIT { print "INIT 2\n" }
BEGIN { print "BEGIN 2\n" }
CHECK { print "CHECK 2\n" }
END { print "END 2\n" }
> BEGIN 1
> BEGIN 2
> CHECK 2
> CHECK 1
> INIT 1
> INIT 2
> normal
> END 2
> END 1
Lets say you come up with some really great chunks of perl code that you want to use in several different programs. Perhaps you have some subroutines that are especially handy, and perhaps they have some private data associated with them. The best place to put code to be used in many different programs is in a "Perl Module", and then "use" that module.
A perl module is really just a file with an invented name and a ".pm" extension. The "pm" is short for "perl moduled". If you had some handy code for modeling a dog, you might put it in a module called Dog.pm, and then you would use the "use" statement to read in the module.
The content of a perl module is any valid perl code. Generally, perl modules contain declarations, such as subroutine declarations and possibly declarations of private or public variables. These declared subroutines can be called and public variables can be accessed by any perl script that uses the module.
It is standard convention that all perl modules start out with a "package" declaration that declares the package namespace to be the same as the module name. After any new package declaration you will need to turn warnings, etc back on.
Here is an example of our Dog module.
###filename: Dog.pm
package Dog;
use warnings; use strict; use Data::Dumper;
sub Speak { print "Woof!\n"; }
1; # MUST BE LAST STATEMENT IN FILE
All perl modules must end with "1;"
otherwise you will get a compile error:
SortingSubs.pm did not return a true value\
The "use" statement allows a perl script to bring in a perl module and use whatever declarations have been made available by the module. Continuing our example, a file called script.pl could bring in the Dog module like this:
use Dog;
Dog::Speak;
> Woof!
Both files, Dog.pm and script.pl, would have to be in the same directory.
The Dog module declares its package namespace to be Dog. The module then declares a subroutine called "speak", which, like any normal subroutine, ends up in the current package namespace, Dog. Once the Dog module has been used, anyone can call the subroutine by calling Dog::Speak;
The "use" statement can be formally defined as this:
use MODULENAME ( LISTOFARGS );
The "use" statement is exactly equivalent to this:
BEGIN
{
require MODULENAME;
MODULENAME->import( LISTOFARGS );
}
The MODULENAME follows the package namespace convention, meaning it would be either a single identifier or multiple identifiers separated by double-colons. These are all valid MODULENAMES:
use Dog;
use Pets::Dog;
use Pets::Dog::GermanShepard;
use Pets::Cat::Perian;
User created module names should be mixed case. Module names with all lower case are reserved for built in pragmas, such as "use warnings;" Module names with all upper case letters are just ugly and could get confused with built in words.
The "require" statement is what actually reads in the module file.
When performing the search for the module file, "require" will translate the double-colons into whatever directory separator is used on your system. For Linux style systems, it would be a "/". So perl would look for Pets::Dog::GermanShepard in Pets/Dog/ for a file called GermanShepard.pm
The "require" statement will look for the module path/file in all the directories listed in a global array called @INC. Perl will initialize this array to some default directories to look for any modules. If you want to create a subdirectory just for your modules, you can add this subdirectory to @INC and perl will find any modules located there.
Because the "require" statement is in a BEGIN block, though, it will execute immediately after being compiled. So this will not work:
push(@INC,'/home/username/perlmodules');
use Dogs;
This is because the "push" statement will get compiled and then be scheduled for execution after the entire program has been compiled. The "use" statement will get compiled and execute immediately, before the "push" is executed, so @INC will not be changed when "use" is called.
You could say something like this:
BEGIN { push(@INC,'/home/username/perlmodules'); }
use Dogs;
The "use lib" statement is my preferred way of adding directory paths to the @INC array, because it does not need a BEGIN block. Just say something like this:
use lib '/home/username/perlmodules';
Also, for you Linux heads, note that the home directory symbol "~" is only meaningful in a linux shell. Perl does not understand it. So if you want to include a directory under your home directory, you will need to call "glob" to translate "~" to something perl will understand. The "glob" function uses the shell translations on a path.
use lib glob('~/perlmodules');
use Dogs;
The "require" statement also searches for MODULENAME in any directories listed in the environment variable called PERL5LIB. The PERL5LIB variable is a colon separated list of directory paths. Consult your shell documentation to determine how to set this environment variable.
If you don't have PERL5LIB set, perl will search for MODULENAME in any directory listed in the PERLLIB environment variable.
Once the require statement has found the module, perl compiles it. Because the require statement is in a BEGIN block, the module gets executed immediately as well.
This means any executable code gets executed. Any code that is not a declaration will execute at this point.
The MODULENAME->import statement is then executed.
The MODULENAME->import(LISTOFARGS) statement is a "method call", which has not been introduced yet. A method call is a fancy way of doing a subroutine call with a couple of extra bells and whistles bolted on.
Basically, if your perl module declares a subroutine called "import" then it will get executed at this time.
More advancedly, one of the bells and whistles of a method call is a thing called "inheritance", which has not been introduced yet. So, to be more accurate, if your perl module OR ITS BASE CLASS(ES) declares a subroutine called "import" then it will get executed at this time.
The import method is a way for a module to import subroutines or variables to the caller's package. This happens when you use Data::Dumper in your script. Which is why you can say
use Data::Dumper;
print Dumper \@var;
instead of having to say:
use Data::Dumper;
print Data::Dumper \@var;
A subroutine called "Dumper" gets imported into your package namespace.
The following example shows the complete execution timeline during a use statement.
#!/usr/local/bin/perl
###filename:script.pl
use warnings; use strict; use Data::Dumper;
warn "just before use Dog";
use Dog ('GermanShepard');
warn "just after use Dog";
Dog::Speak;
###filename:Dog.pm
package Dog;
use warnings; use strict; use Data::Dumper;
warn "executing normal code";
sub Speak { print "Woof!\n"; }
sub import {
warn "calling import";
print "with the following args\n";
print Dumper \@_;
}
1; # MUST BE LAST STATEMENT IN FILE
> executing normal code at Dog.pm line 4.
> calling import at Dog.pm line 7.
> with the following args
> $VAR1 = [
> 'Dog',
> 'GermanShepard'
> ];
> just before use Dog at ./script.pl line 4.
> just after use Dog at ./script.pl line 6.
> Woof!
The bless() function is so simple that people usually have a hard time understanding it because they make it far more complicated than it really is. All bless does is change the string that would be returned when ref() is called. The bless() function is the basis for Object Oriented Perl, but bless() by itself is overwhelmingly simple.
Quick reference refresher: Given an array referent, @arr, and a reference, $rarr=\@arr, then calling ref($rarr) will return the string "ARRAY".
my @arr=(1,2,3); # referent
my $rarr = \@arr; # reference to referent
my $str = ref($rarr); # call ref()
warn "str is '$str'";
> str is 'ARRAY'
Normally, ref() will return SCALAR, ARRAY, HASH, CODE, or empty-string depending on what type of referent it is referred to.
warn ref(\4);
warn ref([]);
warn ref({});
warn ref(sub{});
warn "'".ref(4)."'";
> SCALAR at ./script.pl line 4.
> ARRAY at ./script.pl line 5.
> HASH at ./script.pl line 6.
> CODE at ./script.pl line 7.
> '' at ./script.pl line 8.
The bless function takes a reference and a string as input.
The bless function modifies the referent pointed to by the reference and attaches the given string such that ref() will return that string.
The bless function will then return the original reference.
bless REFERENCE, STRING;
Here is an example of bless() in action. Note this is exactly the same as the code in the first example, but with one line added to do the bless:
my @arr=(1,2,3); # referent
my $rarr = \@arr; # reference to referent
bless($rarr, "Counter");
my $str = ref($rarr); # call ref()
warn "str is '$str'";
> str is 'Counter'
Since bless() returns the reference, we can call ref() on the return value and accomplish it in one line:
my $sca=4;
warn ref(bless(\$sca,"Four"));
warn ref(bless([],"Box"));
warn ref(bless({},"Curlies"));
warn ref(bless(sub{},"Action"));
> Four at ./script.pl line 5.
> Box at ./script.pl line 6.
> Curlies at ./script.pl line 7.
> Action at ./script.pl line 8.
All bless() does is affect the value returned by ref(). That is it.
You might be wondering why the word "bless" was chosen. If a religious figure took water and blessed it, then people would refer to it as "holy water". The constitution and makeup of the water did not change, however it was given a new name, and because of that name it might be used differently.
In perl, bless() changes the name of a referent. It does not affect the contents of the referent, only the name returned by ref(). But because of this new name, the referent might be used differently or behave differently. We would see this difference with method calls.
We have seen method calls before. The MODULENAME->import(LISTOFARGS) was a method call, but we had to do some handwaving to get beyond it, calling it a fancy subroutine call.
Quick review of package qualified subroutine names: When you declare a subroutine, it goes into the current package namespace. You can call the subroutine using its short name if you are still in the package. Or you can use the fully qualified package name, and be guaranteed it will work every time.
package Dog;
sub Speak { print "Woof\n"; }
Speak;
Dog::Speak;
> Woof
> Woof
A method call is similar. Here is the generic definition:
INVOCANT -> METHOD ( LISTOFARGS );
The INVOCANT is the thing that "invoked" the METHOD. An invocant can be several different things, but the simplest thing it can be is just a bareword package name to go look for the subroutine called METHOD.
Dog -> Speak;
> Woof
So it is almost the same as using a package qualified subroutine name Dog::Speak. So what is different?
First, the INVOCANT always gets unshifted into the @_ array in the subroutine call.
package Dog;
use warnings; use strict; use Data::Dumper;
sub Speak {
print Dumper \@_;
my $invocant = shift(@_); # 'Dog'
my $count = shift(@_); # 3
for(1 .. $count) { print "Woof\n"; }
}
Dog -> Speak (3);
> $VAR1 = [
> 'Dog',
> 3
> ];
> Woof
> Woof
> Woof
This may not seem very useful, but an INVOCANT can be many different things, some more useful than others.
The second difference between a subroutine call and a method call is inheritance.
Say you want to model several specific breeds of dogs. The specific breeds of dogs will likely be able to inherit some behaviours (subroutine/methods) from a base class that describes all dogs. Say we model a German Shepard that has the ability to track a scent better than other breeds. But German Shepards still bark like all dogs.
###filename:Dog.pm
package Dog;
use warnings; use strict; use Data::Dumper;
sub Speak {
my $invocant = shift(@_);
warn "invocant is '$invocant'";
my $count = shift(@_);
for(1 .. $count) { warn "Woof"; }
}
1;
###filename:Shepard.pm
package Shepard;
use base Dog;
sub Track { warn "sniff, sniff"; }
1;
#!/usr/local/bin/perl
###filename:script.pl
use Shepard;
Shepard->Speak(2);
Shepard->Track;
> invocant is 'Shepard' at Dog.pm line 6.
> Woof at Dog.pm line 8.
> Woof at Dog.pm line 8.
> sniff, sniff at Shepard.pm line 4.
Notice that script.pl used Shepard, not Dog. And script.pl always used Shepard as the invocant for its method calls. When script.pl called Shepard->Speak, perl first looked in the Shepard namespace for a subroutine called Shepard::Speak. It did not find one. So then it looked and found a BASE of Shepard called Dog. It then looked for a subroutine called Dog::Speak, found one, and called that subroutine.
Also notice that the subroutine Dog::Speak received an invocant of "Shepard". Even though perl ended up calling Dog::Speak, perl still passes Dog::Speak the original invocant, which was "Shepard" in this case.
Shepard INHERITED the Speak subroutine from the Dog package.
The unexplained bit of magic is that inheritance uses the "use base" statement to determine what packages to inherit from.
This statement:
use base MODULENAME;
is functionally identical to this:
BEGIN
{
require MODULENAME;
push(@ISA, MODULENAME);
}
The require statement goes and looks for MODULENAME.pm using the search pattern that we described in the "use" section earlier.
The push(@ISA,MODULENAME) is new. When a method call looks in a package namespace for a subroutine and does not find one, it will then go through the contents of the @ISA array. The @ISA array contains any packages that are BASE packages of the current package.
The @ISA array is named that way because "Shepard" IS A "Dog", therefore ISA.
The search order is depth-first, left-to-right. This is not necessarily the "best" way to search, but it is the way perl searches, so you will want to learn it. If this approach does not work for your application, you can change it with a module from CPAN.
Here is perl's default inheritance tree:
Imagine a Child module has the following family inheritance tree:
Perl will search for Child->Method through the inheritance tree in the following order:
Child
Father
FathersFather
FathersMother
Mother
MothersFather
MothersMother
The "isa" method will tell you if BASEPACKAGE exists anywhere in the @ISA inheritance tree.
Child->isa("MothersMother"); # TRUE
Child->isa("Shepard"); # FALSE
The "can" method will tell you if the INVOCANT can call METHODNAME successfully.
Shepard->can("Speak"); # TRUE (Woof)
Child->can("Track"); # FALSE (can't track a scent)
So far we have only used bareword invocants that correspond to package names.
Shepard->Track;
Perl allows a more interesting invocant to be used with method calls: a blessed referent.
Remember bless() changes the string returned by ref(). Well, when using a reference as an invocant, perl will call ref() on the reference and use the string returned as starting package namespace to begin searching for the method/subroutine.
Here is our simple Dog example but with a blessed invocant.
###filename:Dog.pm
package Dog;
use warnings; use strict; use Data::Dumper;
sub Speak {
my $invocant = shift(@_);
warn "invocant is '$invocant'";
my $count = shift(@_);
for(1 .. $count) { warn "Woof"; }
}
1;
#!/usr/local/bin/perl
###filename:script.pl
use Dog;
my $invocant=bless {},'Dog'; ### BLESSED INVOCANT
$invocant->Speak(2);
invocant is 'Dog=HASH(0x8124394)' at Dog.pm line 6.
Woof at Dog.pm line 8.
Woof at Dog.pm line 8.
The my $invocant=bless {},"Dog"; is the new line. The bless part creates an anonymous hash, {}, and blesses it with the name "Dog". If you called ref($invocant), it would return the string "Dog".
So perl uses "Dog" as its "child" class to begin its method search through the hierarchy tree. When it finds the method, it passes the original invocant, the anonmous hash, to the method as the first argument.
Well, since we have an anonymous hash passed around anyway, maybe we could use it to store some information about the different dogs that we are dealing with. In fact, we already know all the grammar we need to know about Object Oriented Perl Programming, we just need to speak different sentences now.
So far, all the perl coding we have done has been "procedural" perl. When you hear "procedural" think of "Picard", as in Captain Picard of the starship Enterprise. Picard always gave the ship's computer commands in the form of procedural statements.
Computer, set warp drive to 5.
Computer, set shields to "off".
Computer, fire weapons: phasers and photon torpedoes.
The subject of the sentences was always "Computer". In procedural programming, the subject "computer" is implied, the way the subject "you" is implied in the sentence: "Stop!"
The verb and direct object of Picard's sentences become the subroutine name in proceedural programming. Whatever is left become arguments passed in to the subroutine call.
set_warp(5);
set_shield(0);
fire_weapons qw(phasers photon_torpedoes);
Object oriented perl does not use an implied "Computer" as the subject for its sentences. Instead, it uses what was the direct object in the procedural sentences and makes it the subject in object oriented programming.
Warp Drive, set yourself to 5.
Shields, set yourself to "off".
Phasors, fire yourself.
Torpedoes, fire yourself.
But how would we code these sentences?
Let's start with a familiar example, our Dog module. Assume we want to keep track of several dogs at once. Perhaps we are coding up an inventory system for a pet store.
First, we want a common way to handle all pets, so we create an Animal.pm perl module. This module contains one subroutine that takes the invocant and a Name, puts the Name into a hash, blesses the hash, and returns a reference to the hash. This return value becomes a "Animal" object. This subroutine is an object contructor.
Then we create a Dog module that uses Animal as its base to get the contructor. We then add a method to let dogs bark. The method prints the name of the dog when they bark so we know who said what.
The script.pl creates three dogs and stores them in an array. The script then goes through the array and calls the Speak method on each object.
###filename:Animal.pm
package Animal;
sub New
{
my $invocant=shift(@_);
my $name=shift(@_);
return bless({Name=>$name},$invocant);
}
1;
###filename:Dog.pm
package Dog;
use base Animal;
sub Speak {
my $obj=shift;
my $name=$obj->{Name};
warn "$name says Woof";
}
1;
#!/usr/local/bin/perl
###filename:script.pl
use Dog;
my @pets;
# create 3 Dog objects and put them in @pets array
foreach my $name qw(Butch Spike Fluffy)
{ push(@pets, Dog->New($name)); }
# have every pet speak for themselves.
foreach my $pet (@pets)
{ $pet->Speak; }
> Butch says Woof at Dog.pm line 7.
> Spike says Woof at Dog.pm line 7.
> Fluffy says Woof at Dog.pm line 7.
Notice the last foreach loop in script.pl says $pet->Speak. This is object oriented programming, because if you translated that statement to English, it would be "Pet, speak for yourself". The subject of the sentence is "Pet", rather than the implied "Computer" of procedural programming.
Object Oriented Programming statements are of the form:
$subject -> verb ( adjectives, adverbs, etc );
The term "class" is just an Object Oriented way of saying "package and module".
Polymorphism is a real fancy way of saying having different types of objects that have the same methods.
Expanding our previous example, we might want to add a Cat class to handle cats at the pet store.
###filename:Cat.pm
package Cat;
use base Animal;
sub Speak {
my $obj=shift;
my $name=$obj->{Name};
warn "$name says Meow";
}
1;
Then we modify script.pl to put some cats in the @pets array.
#!/usr/local/bin/perl
###filename:script.pl
use Dog; use Cat;
my @pets;
#create some dog objects
foreach my $name qw(Butch Spike Fluffy)
{ push(@pets, Dog->New($name)); }
# create some cat objects
foreach my $name qw(Fang Furball Fluffy)
{ push(@pets, Cat->New($name)); }
# have all the pets say something.
foreach my $pet (@pets)
{ $pet->Speak; } # polymorphism at work
> Butch says Woof at Dog.pm line 7.
> Spike says Woof at Dog.pm line 7.
> Fluffy says Woof at Dog.pm line 7.
> Fang says Meow at Cat.pm line 7.
> Furball says Meow at Cat.pm line 7.
> Fluffy says Meow at Cat.pm line 7.
Notice how the last loop goes through all the pets and has each one speak for themselves. Whether its a dog or cat, the animal will say whatever is appropriate for its type.
This is polymorphism. The code processes a bunch of objects and calls the same method on each object. And each object just knows how to do what it should do.
SUPER:: is an interesting bit of magic that allows a child object with a method call that same method name in its parent's class.
Back to the dogs. To shorten the example, the constructor New was moved to Dog.pm. The Shepard module uses Dog as its base, and has a Speak method that growls, and then calls its ancestor's Dog version of speak.
###filename:Dog.pm
package Dog;
sub New {
return bless({Name=>$_[1]},$_[0]);
}
sub Speak {
my $name=$_[0]->{Name};
warn "$name says Woof";
}
1;
###filename:Shepard.pm
package Shepard;
use base Dog;
sub Speak {
my $name=$_[0]->{Name};
warn "$name says Grrr";
$_[0]->SUPER::Speak; ### SUPER
}
1;
#!/usr/local/bin/perl
###filename:script.pl
use warnings; use strict; use Data::Dumper;
use Shepard;
my $dog=Shepard->New("Spike");
$dog->Speak;
> Spike says Grrr at Shepard.pm line 6.
> Spike says Woof at Dog.pm line 8.
Without the magic of SUPER, the only way that Shepard can call Dog's version of speak is to use a fully package qualified name Dog::Speak(); But this scatters hardcoded names of the base class throughout Shepard, which would make changing the base class a lot of work.
If Shepard's version of Speak simply said $_[0]->Speak, it would get into an infinitely recursive loop. SUPER is a way of saying, "look at my ancestors and call their version of this method."
There are some limitations with SUPER. Consider the big family tree inheritance diagram in the "use base" section of this document (the one with Child as the root, Father and Mother as parents, and FathersFather, FathersMother, etc as grandparents).
Imagine an object of type "Child". If "Father" has a method called Speak and that method calls SUPER::Speak, the only modules that will get looked at is "FathersFather" and "FathersMother". SUPER looks up the hierarchy starting at the class from where it was called. This means if the method you wanted FathersFather to call was in MothersMother, then SUPER will not work.
This could be considered a good thing, since you would assume that Father was designed only knowing about FathersFather and FathersMother. When Father was coded, MothersMother was a complete stranger he would not meet for years to come. So designing Father to rely on his future, have-not-even-met-her-yet mother-in-law, could be considered a bad thing.
However, it is legitimate to have what you might consider to be "universal" methods that exist for every class. Instead of a class called "Child" imagine a class called "CoupleAboutToGetMarried", and every base class has a method called "ContributeToWedding". In that case, every class could do its part, and then call SUPER::ContributeToWedding. The FatherOfTheBride would pay for the wedding, the FatherOfTheGroom would pay for the rehersal dinner, and so on and so forth.
Unfortunately, there is no easy, built-in way to do this in perl.
I will refer you to the "NEXT.pm" module available on CPAN.
SUPER does have its uses, though. Many times a class might exist that does ALMOST what you want it to do. Rather than modify the original code to do what you want it to, you could instead create a derived class that inherits the base class and rewrite the method to do what you want it to do. For example, you might want a method that calls its parent method but then multiplies the result by minus one or something. In cases like this, SUPER will do the trick.
Object destruction occurs when all the references to a specific object have gone out of lexical scope, and the object is scheduled for garbage collection. Just prior to deleting the object and any of its internal data, perl will call the DESTROY method on the object. If no such method exists, perl silently moves on and cleans up the object data.
###filename:Dog.pm
package Dog;
sub New {
return bless({Name=>$_[1]},$_[0]);
}
sub DESTROY {
warn (($_[0]->{Name})." has been sold");
}
1;
#!/usr/local/bin/perl
###filename:script.pl
use warnings; use strict; use Data::Dumper;
use Dog;
my $dog=Dog->New("Spike");
$dog=undef;
> Spike has been sold at Dog.pm line 7.
The DESTROY method has similar limitations as SUPER. With an object that has a complex hierarchical family tree, perl will only call the FIRST method of DESTROY that it finds in the ancestry. If Mother and Father both have a DESTROY method, then Mother's not going to handle her demise properly and you will likely have ghosts when you run your program.
The NEXT.pm module on CPAN also solves this limitation.
The basis for code reuse in perl is a module. A perl module is a file that ends in ".pm" and declares a package namespace that (hopefully) matches the name of the file. The module can be designed for procedural programming or object oriented programming (OO). If the module is OO, then the module is sometimes referred to as a "class".
The code in a perl module can be made available to your script by saying "use MODULE;" The "use" statement will look for the module in the directories listed in the PERL5LIB environment variable and then the directories listed in the @INC variable. The best way to add directories to the @INC variable is to say
use lib "/path/to/dir";
Any double-colons (::) in the module name being used get converted to a directory separator symbol of the operating system.
If the module is designed for procedural programming, it will provide subroutine declarations that can be called like normal subroutines. If the module is designed for object oriented use, it will declare subroutines that will be used as constructors or methods.
Constructors are subroutines that create a reference to some variable, use the reference to bless the variable into the class, and then return the reference. Once its referent is blessed, it can be used as an object, and the reference is a handy way of passing the object around.
The object is usually a hash. Keys to the hash correspond to object attribute names, and the Values correspond to the attribute values specific to that particular instance. In the Animal.pm module example, one key was "Name", and different instances had Name values of "Fluffy", "Spike", and so on.
The best way of calling a constructor is to use the arrow operator:
my $object = Classname->Constructor(arguments);
In the Animal.pm class, this would look like:
my $pet = Animal->New('Spike');
The name of the constructor can be any valid subroutine name, but is usually "new" or "New".
Once an instance of an object has been constructed, methods can be called on the instance to get information, change values, perform operations, etc. A method is simply a subroutine that receives a reference to the instance variable as its first argument. Methods should be thought of as "actions" to be performed on the instance, or "verbs" in a sentences with instances being the "subject".
In the above examples, "Speak" was a method that used the Name of the instance to print out "$name says woof". The preferred way of calling a method is using the arrow method.
$ObjectInstance -> Method ( list of arguments );
In the Animal.pm example, this would look like:
$pet->Speak;
Classes can inherit methods from base classes. This allows many similar classes to put all their common methods in a single base class. To have a class inherit from a base class, use the "use base" statement.
use base BaseClassName;
In one example above, the Cat and Dog classes both inherit from a common Animal class. Both Dog and Cat classes inherit the constructor "New" method from the Animal base class.
The class inheriting from a base class is called a "derived class".
Classes can override the methods of their base classes. If a base class contains a method called "MethodName", then a derived class can override the base class method by declaring its own subroutine called MethodName.
In the examples above, the GermanShepard derived class overrode the Dog base class Speak method with its own method.
If a derived class overrides a method of its base class, it may want to call its base class method. The only way to accomplish this is with the SUPER:: pseudopackage name. The GermanShepard method named Speak called the Dog version of Speak by calling:
$obj->SUPER::Speak;
CPAN is an acronym for "Comprehensive Perl Archive Network". There is a CPAN website, which contains a plethora of perl module for anyone to download. There is also a CPAN perl module, which provides a shell interface for automating the downloading of perl modules from the CPAN website. A "perldoc" utility comes with perl that allows viewing of POD, which is "Plain Old Documentation" embedded within the perl modules downloaded from CPAN. And finally, there is a "h2xs" utility, which automates the creation of a module to be uploaded to CPAN.
CPAN is a website that contains all things perl: help, FAQs, source code to install perl, and most importantly, a plethora of perl module so that you can re-use someone else's code.
CPAN contains a number of search engines. Once you find a module that might do what you need, you can view the README file that is usually available online before actually downloading the module. If the README looks promising, then download the tarball, which will be a file with a tar.gz extension.
Here is the standard installation steps for a module. This example is for the NEXT.pm module, which is contained in NEXT-0.60.tar.gz (you should use the latest version, if available.)
> gunzip NEXT-0.60.tar.gz
> tar -xf NEXT-0.60.tar
> cd NEXT-0.60
From here, most modules install with the exact same commands:
> perl Makefile.PL
> make
> make test
> su root
> make install
> exit
The "make install" step requires root priveledges. The "exit" step is shown just so you remember to log out from root.
If you do not have root priveledges and the module is pure perl (just a .pm file), then you can copy the .pm file to your home directory (or anywhere you have read/write priveledges), and then set your PERL5LIB environment variable to point to that directory.
The CPAN.pm module is a module that automates the installation process. you give it the name of a module, and it downloads it from the web, untars it, and installs it for you. More interestingly, it will install any dependencies for you as well. If you install a module that requires a separate module, it installs both modules for you with one command.
CPAN.pm will want you to have lynx installed on your machine. Lynx is a text-based webbrowser. CPAN.pm will also want ncftpget, which is an Internet file transfer program for scripts. Install these on your system before running the CPAN module.
The CPAN.pm module is run from a shell mode as root (you need root priviledges to do the install). Change to root, and then run the CPAN.pm module shell.
> su root
> perl -MCPAN -e shell
The first time it is run, it will ask you a bunch of configuration questions. Most can be answered with the default value (press <return>).
Here is a log from the CPAN being run for the first time on my machine:
Are you ready for manual configuration? [yes]
CPAN build and cache directory? [/home/greg/.cpan]
Cache size for build directory (in MB)? [10]
Perform cache scanning (atstart or never)? [atstart]
Cache metadata (yes/no)? [yes]
Your terminal expects ISO-8859-1 (yes/no)? [yes]
Policy on building prerequisites (follow, ask or ignore)? [ask]
Where is your gzip program? [/usr/bin/gzip]
Where is your tar program? [/bin/tar]
Where is your unzip program? [/usr/bin/unzip]
Where is your make program? [/usr/bin/make]
Where is your lynx program? []
> /usr/bin/lynx
Where is your wget program? [/usr/bin/wget]
Where is your ncftpget program? []
> /usr/bin/ncftpget
Where is your ftp program? [/usr/bin/ftp]
What is your favorite pager program? [/usr/bin/less]
What is your favorite shell? [/bin/bash]
Parameters for the 'perl Makefile.PL' command?
Your choice: []
Parameters for the 'make' command?
Your choice: []
Parameters for the 'make install' command?
Your choice: []
Timeout for inactivity during Makefile.PL? [0]
Your ftp_proxy?
Your http_proxy?
Your no_proxy?
Select your continent (or several nearby continents) []